" Vim syntax file
" Language:	po (GNU gettext)
" Maintainer:	Sung-Hyun Nam <address@hidden>
" Last Change:	6.05.2003
" Last change made by Слободан Средојевић <address@hidden> and Александар Урошевић <address@hidden

" remove any old syntax stuff hanging around
syn clear

syn match  poComment	"^#.*$"
syn match  poSources	"^#:.*$"
syn match  poStatement	"^\(msgid\|msgstr\)"
syn match  poSpecial	contained "\\\(x\x\+\|\o\{1,3}\|.\|$\)"
syn match  poFormat	"%\(\d\+\$\)\=[-+' #0*]*\(\d*\|\*\|\*\d\+\$\)\(\.\(\d*\|\*\|\*\d\+\$\)\)\=\([hlL]\|ll\)\=\([diuoxXfeEgGcCsSpn]\|\[\^\=.[^]]*\]\)" contained
syn match  poFormat	"%%" contained
syn region poString	start=+"+ skip=+\\\\\|\\"+ end=+"+
			\ contains=poSpecial,poFormat

if !exists("did_po_syntax_inits")
  let did_po_syntax_inits = 1
  " The default methods for highlighting.  Can be overridden later.
  hi link poComment	Comment
  hi link poSources	PreProc
  hi link poStatement	Statement
  hi link poSpecial	Special
  hi link poFormat	poSpecial
  hi link poString	String
endif

let b:current_syntax = "po"

" vim:set ts=8 sts=8 sw=8 noet:

"
" ###########
"


" po.vimrc: VIM resource for 'po' file editing.

set   com=
set   path=.,..,../src,,

" find a non-translated msg string /forward
imap<F9> <ESC>:call FindNonTransMsgFw()<CR>z.$i

" find a non-translated msg string /backward
imap<C-F9> <ESC>:call FindNonTransMsgBw()<CR>z.$i

" remove fuzzy
imap<F4> <ESC>?#,fuzzy\\|#, fuzzy<CR>:let @/ = ""<CR>ddi

" insert fuzzy
imap<F5> <ESC>{:let @/ = ""<CR>o#, fuzzy<ESC>i

" find next fuzzy
imap<F2> <ESC>/#,fuzzy\\|#, fuzzy<CR>:let @/ = ""<CR>/msgstr<CR>:let @/ = ""<CR>$i

" find previous fuzzy
imap<F1> <ESC>{?#,fuzzy\\|#, fuzzy<CR>:let @/ = ""<CR>/msgstr<CR>:let @/ = ""<CR>$i

" fill last-translator,language team and content-type 
imap<F7> <ESC>/Last-Translator:<CR>f:ld$a<ESC>:put = name_and_email<CR>kJ/Language-Team:<CR>f:ld$a<ESC>:put = lang_team<CR>kJ/Content-Type:<CR>f:ld$a<ESC>:put = content_type<CR>kJi

" change po revision date
imap<F6> <ESC>/PO-Revision-Date:<CR>f:ld$a <C-R>=strftime("%Y-%m-%d %H:%M%z")<CR>\n"<ESC>i

" show statistics
imap<F12> <ESC>:w<CR>:!msgfmt --statistics %<CR>

" put original msgid string into msgstr quotes "".
imap<F11> <ESC> }?^msgid<CR>f"ly$/^msgstr<CR>:let @/ = ""<CR>f"plxi

" erase the translated message
imap<F3> <ESC> }?^msgstr<CR>:let @/ = ""<CR>f"lc}"<ESC>i

function! FindNonTransMsgFw()
  let lnum = line(".") + 1
  let enum = line("$")
  let found = 0
  while lnum < enum
    let line = getline(lnum)
    let lnum = lnum + 1
    if line == "msgstr \"\""
      let blank = getline(lnum)
      if blank == ""
        let found = found + 1
        exec "normal " . lnum . "ggk"
        let lnum = enum
      endif
      let lnum = lnum + 1
    endif
  endwhile
  if found < 1
    echo "Cannot find non-translated msg"
  endif
endfun


function! FindNonTransMsgBw()
  exec "normal k"
  exec "normal ?msgstr \"\"\<CR>"
  exec "normal " "j"
  let myblank = getline(".")
    if myblank == ""
      exec "normal " "k"
     else
      call FindNonTransMsgBw()
    endif 
endfun