[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
[PULL 23/33] tests/tcg/s390x: Add sam.S
From: |
Thomas Huth |
Subject: |
[PULL 23/33] tests/tcg/s390x: Add sam.S |
Date: |
Mon, 27 Feb 2023 12:36:11 +0100 |
From: Ilya Leoshkevich <iii@linux.ibm.com>
Add a small test to prevent regressions.
Signed-off-by: Ilya Leoshkevich <iii@linux.ibm.com>
Signed-off-by: Richard Henderson <richard.henderson@linaro.org>
Message-Id: <20221129015328.55439-1-iii@linux.ibm.com>
Message-Id: <20230220184052.163465-7-richard.henderson@linaro.org>
Signed-off-by: Thomas Huth <thuth@redhat.com>
---
tests/tcg/s390x/Makefile.softmmu-target | 1 +
tests/tcg/s390x/sam.S | 67 +++++++++++++++++++++++++
2 files changed, 68 insertions(+)
create mode 100644 tests/tcg/s390x/sam.S
diff --git a/tests/tcg/s390x/Makefile.softmmu-target
b/tests/tcg/s390x/Makefile.softmmu-target
index bcbe9367ef..725b6c598d 100644
--- a/tests/tcg/s390x/Makefile.softmmu-target
+++ b/tests/tcg/s390x/Makefile.softmmu-target
@@ -8,3 +8,4 @@ QEMU_OPTS=-action panic=exit-failure -kernel
TESTS += unaligned-lowcore
TESTS += bal
+TESTS += sam
diff --git a/tests/tcg/s390x/sam.S b/tests/tcg/s390x/sam.S
new file mode 100644
index 0000000000..4cab2dd200
--- /dev/null
+++ b/tests/tcg/s390x/sam.S
@@ -0,0 +1,67 @@
+/* DAT on, home-space mode, 64-bit mode */
+#define DAT_PSWM 0x400c00180000000
+#define VIRTUAL_BASE 0x123456789abcd000
+
+ .org 0x8e
+program_interruption_code:
+ .org 0x150
+program_old_psw:
+ .org 0x1d0 /* program new PSW */
+ .quad 0,pgm_handler
+ .org 0x200 /* lowcore padding */
+
+ .globl _start
+_start:
+ lctlg %c13,%c13,hasce
+ lpswe dat_psw
+start_dat:
+ sam24
+sam24_suppressed:
+ /* sam24 should fail */
+fail:
+ basr %r12,%r0
+ lpswe failure_psw-.(%r12)
+pgm_handler:
+ chhsi program_interruption_code,6 /* specification exception? */
+ jne fail
+ clc suppressed_psw(16),program_old_psw /* correct location? */
+ jne fail
+ lpswe success_psw
+
+ .align 8
+dat_psw:
+ .quad DAT_PSWM,VIRTUAL_BASE+start_dat
+suppressed_psw:
+ .quad DAT_PSWM,VIRTUAL_BASE+sam24_suppressed
+success_psw:
+ .quad 0x2000000000000,0xfff /* see is_special_wait_psw() */
+failure_psw:
+ .quad 0x2000000000000,0 /* disabled wait */
+hasce:
+ /* DT = 0b11 (region-first-table), TL = 3 (2k entries) */
+ .quad region_first_table + (3 << 2) + 3
+ .align 0x1000
+region_first_table:
+ .org region_first_table + ((VIRTUAL_BASE >> 53) & 0x7ff) * 8
+ /* TT = 0b11 (region-first-table), TL = 3 (2k entries) */
+ .quad region_second_table + (3 << 2) + 3
+ .org region_first_table + 0x800 * 8
+region_second_table:
+ .org region_second_table + ((VIRTUAL_BASE >> 42) & 0x7ff) * 8
+ /* TT = 0b10 (region-second-table), TL = 3 (2k entries) */
+ .quad region_third_table + (2 << 2) + 3
+ .org region_second_table + 0x800 * 8
+region_third_table:
+ .org region_third_table + ((VIRTUAL_BASE >> 31) & 0x7ff) * 8
+ /* TT = 0b01 (region-third-table), TL = 3 (2k entries) */
+ .quad segment_table + (1 << 2) + 3
+ .org region_third_table + 0x800 * 8
+segment_table:
+ .org segment_table + ((VIRTUAL_BASE >> 20) & 0x7ff) * 8
+ /* TT = 0b00 (segment-table) */
+ .quad page_table
+ .org segment_table + 0x800 * 8
+page_table:
+ .org page_table + ((VIRTUAL_BASE >> 12) & 0xff) * 8
+ .quad 0
+ .org page_table + 0x100 * 8
--
2.31.1
- [PULL 16/33] target/s390x: Hoist some computation in access_memmove, (continued)
- [PULL 16/33] target/s390x: Hoist some computation in access_memmove, Thomas Huth, 2023/02/27
- [PULL 22/33] tests/tcg/s390x: Add bal.S, Thomas Huth, 2023/02/27
- [PULL 29/33] gitlab-ci.d/buildtest: Disintegrate the build-coroutine-sigaltstack job, Thomas Huth, 2023/02/27
- [PULL 19/33] target/s390x: Use tcg_constant_* for DisasCompare, Thomas Huth, 2023/02/27
- [PULL 20/33] target/s390x: Use tcg_constant_i32 for fpinst_extract_m34, Thomas Huth, 2023/02/27
- [PULL 24/33] configure: Add 'mkdir build' check, Thomas Huth, 2023/02/27
- [PULL 33/33] Deprecate the "-no-acpi" command line switch, Thomas Huth, 2023/02/27
- [PULL 32/33] gitlab-ci.d/base: Mark jobs as interruptible by default, Thomas Huth, 2023/02/27
- [PULL 21/33] target/s390x: Use tcg_constant_* in translate_vx.c.inc, Thomas Huth, 2023/02/27
- [PULL 17/33] s390x/pv: Add support for asynchronous teardown for reboot, Thomas Huth, 2023/02/27
- [PULL 23/33] tests/tcg/s390x: Add sam.S,
Thomas Huth <=
- [PULL 28/33] gitlab-ci.d/buildtest: Remove aarch64-softmmu from the build-system-ubuntu job, Thomas Huth, 2023/02/27
- [PULL 31/33] gitlab-ci.d: Build with --enable-fdt=system by default, Thomas Huth, 2023/02/27
- [PULL 27/33] Updated the FSF address to <https://www.gnu.org/licenses/>, Thomas Huth, 2023/02/27
- [PULL 18/33] target/s390x: Use tcg_constant_* in local contexts, Thomas Huth, 2023/02/27
- [PULL 25/33] qemu-keymap: Silence memory leak warning from Clang's sanitizer, Thomas Huth, 2023/02/27
- [PULL 26/33] meson: fix dependency on qemu-keymap, Thomas Huth, 2023/02/27
- [PULL 30/33] gitlab-ci.d/buildtest-template: Simplify the configure step, Thomas Huth, 2023/02/27
- Re: [PULL 00/33] s390x and testing related patches, Peter Maydell, 2023/02/27