help-gnu-emacs
[Top][All Lists]
Advanced

[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

Re: zoom features


From: Miles Bader
Subject: Re: zoom features
Date: Mon, 04 Jan 2010 18:29:52 +0900

Joseph Brenner <address@hidden> writes:
> Are there any standard fixes for these problems kicking around?

They are not problems, they are intentional.

You apparently want a different functionality; it isn't hard to write a
"global" zoom by frobbing the height of the default face, e.g.:

   (defun increase-default-face-height (&optional steps)
     "Increase the height of the default face by STEPS steps.
   Each step multiplies the height by 1.2; a negative number of steps
   decreases the height by the same amount."
     (interactive
      (list
       (cond ((eq current-prefix-arg '-) -1)
             ((numberp current-prefix-arg) current-prefix-arg)
             ((consp current-prefix-arg) -1)
             (t 1))))
     (let ((frame (selected-frame)))
       (set-face-attribute 'default frame
                           :height (floor
                                    (* (face-attribute 'default :height frame)
                                       (expt 1.3 steps))))))

   (defun decrease-default-face-height (&optional steps)
     "Decrease the height of the default face by STEPS steps.
   Each step divides the height by 1.2; a negative number of steps
   increases the height by the same amount."
     (interactive
      (list
       (cond ((eq current-prefix-arg '-) -1)
             ((numberp current-prefix-arg) current-prefix-arg)
             ((consp current-prefix-arg) -1)
             (t 1))))
     (increase-default-face-height (- steps)))

   (global-set-key [(control =)] 'increase-default-face-height)
   (global-set-key [(control +)] 'increase-default-face-height)
   (global-set-key [(control -)] 'decrease-default-face-height)

-miles

-- 
Success, n. The one unpardonable sin against one's fellows.


reply via email to

[Prev in Thread] Current Thread [Next in Thread]