[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
[bug#28487] [PATCH] cuirass: Add gnu-system build spec.
From: |
Jan Nieuwenhuizen |
Subject: |
[bug#28487] [PATCH] cuirass: Add gnu-system build spec. |
Date: |
Sun, 17 Sep 2017 22:11:57 +0200 |
* build-aux/cuirass/gnu-system.scm: New file. Combines
build-aux/hydra/gnu-system.scm, guix-cuirass/examples/gnu-system.scm and
supports
building a named subset.
(let ((spec #~((#:name . "guix")
(#:url . "git://git.savannah.gnu.org/guix.git")
(#:load-path . ".")
(#:file . "build-aux/cuirass/gnu-system.scm")
(#:proc . hydra-jobs)
(#:arguments (subset . ("hello" "grep")))
(#:branch . "master"))))
(service cuirass-service-type
(cuirass-configuration
(specifications #~(list '#$spec)))))
---
build-aux/cuirass/gnu-system.scm | 376 +++++++++++++++++++++++++++++++++++++++
1 file changed, 376 insertions(+)
create mode 100644 build-aux/cuirass/gnu-system.scm
diff --git a/build-aux/cuirass/gnu-system.scm b/build-aux/cuirass/gnu-system.scm
new file mode 100644
index 000000000..15fdd3e31
--- /dev/null
+++ b/build-aux/cuirass/gnu-system.scm
@@ -0,0 +1,376 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2012, 2013, 2014, 2015, 2016, 2017 Ludovic Courtès
<address@hidden>
+;;; Copyright © 2016 Mathieu Lirzin <address@hidden>
+;;; Copyright © 2017 Jan Nieuwenhuizen <address@hidden>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
+
+;;;
+;;; This file defines build jobs for the Hydra continuation integration
+;;; tool.
+;;;
+
+;; Attempt to use our very own Guix modules.
+(eval-when (compile load eval)
+
+ ;; Ignore any available .go, and force recompilation. This is because our
+ ;; checkout in the store has mtime set to the epoch, and thus .go files look
+ ;; newer, even though they may not correspond.
+ (set! %fresh-auto-compile #t)
+
+ (and=> (assoc-ref (current-source-location) 'filename)
+ (lambda (file)
+ (let ((dir (string-append (dirname file) "/../..")))
+ (format (current-error-port) "prepending ~s to the load path~%"
+ dir)
+ (set! %load-path (cons dir %load-path))))))
+
+(use-modules (guix config)
+ (guix store)
+ (guix grafts)
+ (guix profiles)
+ (guix packages)
+ (guix derivations)
+ (guix monads)
+ ((guix licenses)
+ #:select (gpl3+ license-name license-uri license-comment))
+ ((guix utils) #:select (%current-system))
+ ((guix scripts system) #:select (read-operating-system))
+ ((guix scripts pack)
+ #:select (lookup-compressor self-contained-tarball))
+ (gnu packages)
+ (gnu packages gcc)
+ (gnu packages base)
+ (gnu packages gawk)
+ (gnu packages guile)
+ (gnu packages gettext)
+ (gnu packages compression)
+ (gnu packages multiprecision)
+ (gnu packages make-bootstrap)
+ (gnu packages package-management)
+ (gnu system)
+ (gnu system vm)
+ (gnu system install)
+ (gnu tests)
+ (srfi srfi-1)
+ (srfi srfi-26)
+ (ice-9 match))
+
+;; XXX: Debugging hack: since `hydra-eval-guile-jobs' redirects the output
+;; port to the bit bucket, let us write to the error port instead.
+(setvbuf (current-error-port) _IOLBF)
+(set-current-output-port (current-error-port))
+
+(define (license->alist lcs)
+ "Return LCS <license> object as an alist."
+ ;; Sometimes 'license' field is a list of licenses.
+ (if (list? lcs)
+ (map license->alist lcs)
+ `((name . ,(license-name lcs))
+ (uri . ,(license-uri lcs))
+ (comment . ,(license-comment lcs)))))
+
+(define (package-metadata package)
+ "Convert PACKAGE to an alist suitable for Hydra."
+ `((#:description . ,(package-synopsis package))
+ (#:long-description . ,(package-description package))
+ (#:license . ,(license->alist (package-license package)))
+ (#:home-page . ,(package-home-page package))
+ (#:maintainers . ("address@hidden"))
+ (#:max-silent-time . ,(or (assoc-ref (package-properties package)
+ 'max-silent-time)
+ 3600)) ;1 hour by default
+ (#:timeout . ,(or (assoc-ref (package-properties package) 'timeout)
+ 72000)))) ;20 hours by default
+
+(define (package-job store job-name package system)
+ "Return a job called JOB-NAME that builds PACKAGE on SYSTEM."
+ (lambda ()
+ `((#:job-name . ,(string-append (symbol->string job-name) "." system))
+ (#:derivation . ,(derivation-file-name
+ (parameterize ((%graft? #f))
+ (package-derivation store package system
+ #:graft? #f))))
+ ,@(package-metadata package))))
+
+(define (package-cross-job store job-name package target system)
+ "Return a job called TARGET.JOB-NAME that cross-builds PACKAGE
+for TARGET on SYSTEM."
+ (lambda ()
+ `((#:job-name . ,(string-join (list target (symbol->string job-name)
system)
+ "."))
+ (#:derivation . ,(derivation-file-name
+ (parameterize ((%graft? #f))
+ (package-cross-derivation store package target system
+ #:graft? #f))))
+ ,@(package-metadata package))))
+
+(define %core-packages
+ ;; Note: Don't put the '-final' package variants because (1) that's
+ ;; implicit, and (2) they cannot be cross-built (due to the explicit input
+ ;; chain.)
+ (list gcc-4.8 gcc-4.9 gcc-5 glibc binutils
+ gmp mpfr mpc coreutils findutils diffutils patch sed grep
+ gawk gnu-gettext hello guile-2.0 guile-2.2 zlib gzip xz
+ %bootstrap-binaries-tarball
+ %binutils-bootstrap-tarball
+ (%glibc-bootstrap-tarball)
+ %gcc-bootstrap-tarball
+ %guile-bootstrap-tarball
+ %bootstrap-tarballs))
+
+(define %packages-to-cross-build
+ %core-packages)
+
+(define %cross-targets
+ '("mips64el-linux-gnu"
+ "mips64el-linux-gnuabi64"
+ "arm-linux-gnueabihf"
+ "aarch64-linux-gnu"
+ "powerpc-linux-gnu"
+ "i586-pc-gnu" ;aka. GNU/Hurd
+ "i686-w64-mingw32"))
+
+(define %guixsd-supported-systems
+ '("x86_64-linux" "i686-linux"))
+
+(define (qemu-jobs store system)
+ "Return a list of jobs that build QEMU images for SYSTEM."
+ (define (->alist drv)
+ `((derivation . ,(derivation-file-name drv))
+ (description . "Stand-alone QEMU image of the GNU system")
+ (long-description . "This is a demo stand-alone QEMU image of the GNU
+system.")
+ (license . ,gpl3+)
+ (home-page . ,%guix-home-page-url)
+ (maintainers . ("address@hidden"))))
+
+ (define (->job name drv)
+ (let ((name (symbol-append name (string->symbol ".")
+ (string->symbol system))))
+ `(,name . ,(lambda ()
+ (parameterize ((%graft? #f))
+ (->alist drv))))))
+
+ (define MiB
+ (expt 2 20))
+
+ (if (member system %guixsd-supported-systems)
+ (list (->job 'usb-image
+ (run-with-store store
+ (mbegin %store-monad
+ (set-guile-for-build (default-guile))
+ (system-disk-image installation-os
+ #:disk-image-size
+ (* 1024 MiB)))))
+ (->job 'iso9660-image
+ (run-with-store store
+ (mbegin %store-monad
+ (set-guile-for-build (default-guile))
+ (system-disk-image installation-os
+ #:file-system-type
+ "iso9660")))))
+ '()))
+
+(define (system-test-jobs store system)
+ "Return a list of jobs for the system tests."
+ (define (test->thunk test)
+ (lambda ()
+ (define drv
+ (run-with-store store
+ (mbegin %store-monad
+ (set-current-system system)
+ (set-grafting #f)
+ (set-guile-for-build (default-guile))
+ (system-test-value test))))
+
+ `((derivation . ,(derivation-file-name drv))
+ (description . ,(format #f "GuixSD '~a' system test"
+ (system-test-name test)))
+ (long-description . ,(system-test-description test))
+ (license . ,gpl3+)
+ (home-page . ,%guix-home-page-url)
+ (maintainers . ("address@hidden")))))
+
+ (define (->job test)
+ (let ((name (string->symbol
+ (string-append "test." (system-test-name test)
+ "." system))))
+ (cons name (test->thunk test))))
+
+ (if (member system %guixsd-supported-systems)
+ (map ->job (all-system-tests))
+ '()))
+
+(define (tarball-jobs store system)
+ "Return Hydra jobs to build the self-contained Guix binary tarball."
+ (define (->alist drv)
+ `((derivation . ,(derivation-file-name drv))
+ (description . "Stand-alone binary Guix tarball")
+ (long-description . "This is a tarball containing binaries of Guix and
+all its dependencies, and ready to be installed on non-GuixSD distributions.")
+ (license . ,gpl3+)
+ (home-page . ,%guix-home-page-url)
+ (maintainers . ("address@hidden"))))
+
+ (define (->job name drv)
+ (let ((name (symbol-append name (string->symbol ".")
+ (string->symbol system))))
+ `(,name . ,(lambda ()
+ (parameterize ((%graft? #f))
+ (->alist drv))))))
+
+ ;; XXX: Add a job for the stable Guix?
+ (list (->job 'binary-tarball
+ (run-with-store store
+ (mbegin %store-monad
+ (set-guile-for-build (default-guile))
+ (>>= (profile-derivation (packages->manifest (list guix)))
+ (lambda (profile)
+ (self-contained-tarball "guix-binary" profile
+ #:localstatedir? #t
+ #:compressor
+ (lookup-compressor "xz")))))
+ #:system system))))
+
+(define job-name
+ ;; Return the name of a package's job.
+ (compose string->symbol package-full-name))
+
+(define package->job
+ (let ((base-packages
+ (delete-duplicates
+ (append-map (match-lambda
+ ((_ package _ ...)
+ (match (package-transitive-inputs package)
+ (((_ inputs _ ...) ...)
+ inputs))))
+ (%final-inputs)))))
+ (lambda (store package system)
+ "Return a job for PACKAGE on SYSTEM, or #f if this combination is not
+valid."
+ (cond ((member package base-packages)
+ #f)
+ ((supported-package? package system)
+ (let ((drv (package-derivation store package system
+ #:graft? #f)))
+ (and (substitutable-derivation? drv)
+ (package-job store (job-name package)
+ package system))))
+ (else
+ #f)))))
+
+
+;;;
+;;; Hydra entry point.
+;;;
+
+(define (hydra-jobs store arguments)
+ "Return Hydra jobs."
+ (define subset
+ (match (assoc-ref arguments 'subset)
+ ("core" 'core) ; only build core packages
+ ("hello" 'hello) ; only build hello
+ (((? string?) (? string?) ...) 'list) ; only build selected list
of packages
+ (_ 'all))) ; build everything
+
+ (define (cross-jobs system)
+ (define (from-32-to-64? target)
+ ;; Return true if SYSTEM is 32-bit and TARGET is 64-bit. This hack
+ ;; prevents known-to-fail cross-builds from i686-linux or armhf-linux to
+ ;; mips64el-linux-gnuabi64.
+ (and (or (string-prefix? "i686-" system)
+ (string-prefix? "i586-" system)
+ (string-prefix? "armhf-" system))
+ (string-contains target "64"))) ;x86_64, mips64el, aarch64, etc.
+
+ (define (same? target)
+ ;; Return true if SYSTEM and TARGET are the same thing. This is so we
+ ;; don't try to cross-compile to 'mips64el-linux-gnu' from
+ ;; 'mips64el-linux'.
+ (or (string-contains target system)
+ (and (string-prefix? "armhf" system) ;armhf-linux
+ (string-prefix? "arm" target)))) ;arm-linux-gnueabihf
+
+ (define (pointless? target)
+ ;; Return #t if it makes no sense to cross-build to TARGET from SYSTEM.
+ (and (string-contains target "mingw")
+ (not (string=? "x86_64-linux" system))))
+
+ (define (either proc1 proc2 proc3)
+ (lambda (x)
+ (or (proc1 x) (proc2 x) (proc3 x))))
+
+ (append-map (lambda (target)
+ (map (lambda (package)
+ (package-cross-job store (job-name package)
+ package target system))
+ %packages-to-cross-build))
+ (remove (either from-32-to-64? same? pointless?)
+ %cross-targets)))
+
+ ;; Turn off grafts. Grafting is meant to happen on the user's machines.
+ (parameterize ((%graft? #f))
+ ;; Return one job for each package, except bootstrap packages.
+ (append-map (lambda (system)
+ (case subset
+ ((all)
+ ;; Build everything, including replacements.
+ (let ((all (fold-packages
+ (lambda (package result)
+ (cond ((package-replacement package)
+ (cons* package
+ (package-replacement package)
+ result))
+ ((package-superseded package)
+ result) ;don't build it
+ (else
+ (cons package result))))
+ '()))
+ (job (lambda (package)
+ (package->job store package
+ system))))
+ (append (filter-map job all)
+ (qemu-jobs store system)
+ (system-test-jobs store system)
+ (tarball-jobs store system)
+ (cross-jobs system))))
+ ((core)
+ ;; Build core packages only.
+ (append (map (lambda (package)
+ (package-job store (job-name package)
+ package system))
+ %core-packages)
+ (cross-jobs system)))
+ ((hello)
+ ;; Build hello package only.
+ (if (string=? system (%current-system))
+ (let ((hello (specification->package "hello")))
+ (list (package-job store (job-name hello) hello
system)))
+ '()))
+ ((list)
+ ;; Build selected list of packages only.
+ (if (string=? system (%current-system))
+ (let* ((names (assoc-ref arguments 'subset))
+ (packages (map specification->package names)))
+ (map (lambda (package)
+ (package-job store (job-name package)
+ package system))
+ packages))
+ '()))
+ (else
+ (error "unknown subset" subset))))
+ %hydra-supported-systems)))
--
Jan Nieuwenhuizen <address@hidden> | GNU LilyPond http://lilypond.org
Freelance IT http://JoyofSource.com | Avatar® http://AvatarAcademy.com
- [bug#28484] Some steps and questions for Cuirass, Jan Nieuwenhuizen, 2017/09/17
- [bug#28485] [PATCH 1/3] base: Make working copy writable., Jan Nieuwenhuizen, 2017/09/17
- [bug#28486] [PATCH 2/3] gnu-system: Accept subset with list of package names., Jan Nieuwenhuizen, 2017/09/17
- [bug#28488] [PATCH 3/3] base: Show feedback when build has finished., Jan Nieuwenhuizen, 2017/09/17
- [bug#28487] [PATCH] cuirass: Add gnu-system build spec.,
Jan Nieuwenhuizen <=
- [bug#28487] [PATCH] cuirass: Add gnu-system build spec., Ludovic Courtès, 2017/09/26
- [bug#28487] [PATCH] cuirass: Add gnu-system build spec., Jan Nieuwenhuizen, 2017/09/26
- [bug#28487] [PATCH] cuirass: Add gnu-system build spec., Jan Nieuwenhuizen, 2017/09/26
- [bug#28487] [PATCH] cuirass: Add gnu-system build spec., Ludovic Courtès, 2017/09/26
- [bug#28487] [PATCH] cuirass: Add gnu-system build spec., Jan Nieuwenhuizen, 2017/09/27
- [bug#28487] [PATCH] cuirass: Add gnu-system build spec., Ludovic Courtès, 2017/09/27
- [bug#28487] [PATCH] cuirass: Add gnu-system build spec., Jan Nieuwenhuizen, 2017/09/27
- [bug#28487] [PATCH] cuirass: Add gnu-system build spec., Jan Nieuwenhuizen, 2017/09/27
- [bug#28487] [PATCH] cuirass: Add gnu-system build spec., Ludovic Courtès, 2017/09/28
- bug#28487: [PATCH] cuirass: Add gnu-system build spec., Jan Nieuwenhuizen, 2017/09/28