remainderl on OpenBSD

[Bruno Haible]

On OpenBSD 5.1/SPARC64, remainderl() is also completely broken:
For x = 9.245907126L,
    y = 3.141592654L,
it returns
        0.104314472L,
that is, x - y - 6, instead of x - 3*y.

Workaround added:


2012-03-13  Bruno Haible  <address@hidden>

        remainderl: Bypass broken implementation in OpenBSD 5.1/SPARC.
        * m4/remainderl.m4 (gl_FUNC_REMAINDERL_WORKS): New macro.
        (gl_FUNC_REMAINDERL): Invoke it. If the function does not work, set
        REPLACE_REMAINDERL to 1.
        * doc/posix-functions/remainderl.texi: Mention the OpenBSD 5.1/SPARC
        bug.

--- doc/posix-functions/remainderl.texi.orig    Wed Mar 14 02:36:27 2012
+++ doc/posix-functions/remainderl.texi Wed Mar 14 02:10:23 2012
@@ -14,6 +14,9 @@
 @item
 This function is not declared on some platforms:
 IRIX 6.5.
address@hidden
+This function returns completely wrong values on some platforms:
+OpenBSD 5.1/SPARC.
 @end itemize
 
 Portability problems fixed by Gnulib module @code{remainderl-ieee}:
--- m4/remainderl.m4.orig       Wed Mar 14 02:36:27 2012
+++ m4/remainderl.m4    Wed Mar 14 02:09:51 2012
@@ -1,4 +1,4 @@
-# remainderl.m4 serial 5
+# remainderl.m4 serial 6
 dnl Copyright (C) 2012 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
@@ -47,6 +47,16 @@
     dnl Also check whether it's declared.
     dnl IRIX 6.5 has remainderl() in libm but doesn't declare it in <math.h>.
     AC_CHECK_DECLS([remainderl], , [HAVE_DECL_REMAINDERL=0], [[#include 
<math.h>]])
+
+    save_LIBS="$LIBS"
+    LIBS="$LIBS $REMAINDERL_LIBM"
+    gl_FUNC_REMAINDERL_WORKS
+    LIBS="$save_LIBS"
+    case "$gl_cv_func_remainderl_works" in
+      *yes) ;;
+      *) REPLACE_REMAINDERL=1 ;;
+    esac
+
     m4_ifdef([gl_FUNC_REMAINDERL_IEEE], [
       if test $gl_remainderl_required = ieee && test $REPLACE_REMAINDERL = 0; 
then
         AC_CACHE_CHECK([whether remainderl works according to ISO C 99 with 
IEC 60559],
@@ -129,3 +139,46 @@
   fi
   AC_SUBST([REMAINDERL_LIBM])
 ])
+
+dnl Test whether remainderl() works.
+dnl It produces completely wrong values on OpenBSD 5.1/SPARC.
+AC_DEFUN([gl_FUNC_REMAINDERL_WORKS],
+[
+  AC_REQUIRE([AC_PROG_CC])
+  AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
+  AC_CACHE_CHECK([whether remainderl works], [gl_cv_func_remainderl_works],
+    [
+      AC_RUN_IFELSE(
+        [AC_LANG_SOURCE([[
+#ifndef __NO_MATH_INLINES
+# define __NO_MATH_INLINES 1 /* for glibc */
+#endif
+#include <math.h>
+extern
+#ifdef __cplusplus
+"C"
+#endif
+long double remainderl (long double, long double);
+volatile long double x;
+volatile long double y;
+long double z;
+int main ()
+{
+  /* This test fails on OpenBSD 5.1/SPARC.  */
+  x = 9.245907126L;
+  y = 3.141592654L;
+  z = remainderl (x, y);
+  if (z >= 0.0L)
+    return 1;
+  return 0;
+}
+]])],
+        [gl_cv_func_remainderl_works=yes],
+        [gl_cv_func_remainderl_works=no],
+        [case "$host_os" in
+           openbsd*) gl_cv_func_remainderl_works="guessing no";;
+           *)        gl_cv_func_remainderl_works="guessing yes";;
+         esac
+        ])
+    ])
+])