bug-gnulib
[Top][All Lists]
Advanced

[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

Re: copysignf: don't override undeclared system function


From: Bruno Haible
Subject: Re: copysignf: don't override undeclared system function
Date: Thu, 08 Mar 2012 12:07:31 +0100
User-agent: KMail/4.7.4 (Linux/3.1.0-1.2-desktop; KDE/4.7.4; x86_64; ; )

> On IRIX 6.5, copysignf() exists in libm (at least for certain target ABIs)
> but is not unconditionally declared in the header files. As a result,
> gnulib did not detect this function and provided a replacement - but without
> the rpl_ prefix. Instead the system function can be used.

But for remainderf() the situation is opposite: It is undeclared on IRIX 6.5
and buggy. remainderf (9.316161e+37f, 0.5475547314f) goes into an endless loop.

Similarly for fma() and fmal() which are buggy if not replaced:

__round_d:  bad mantissa (0000000000000000)
test-fma2.h:538: assertion failed
FAIL: test-fma2

test-fma1.h:137: assertion failed
FAIL: test-fmal1
test-fma2.h:93: assertion failed
FAIL: test-fmal2


2012-03-08  Bruno Haible  <address@hidden>

        remainderf: Override buggy system function on IRIX 6.5.
        * m4/remainderf.m4 (gl_FUNC_REMAINDERF_WORKS): New macro.
        (gl_FUNC_REMAINDERF): Invoke it. Don't assume remainderf() is declared
        when it exists.
        * doc/posix-functions/remainderf.texi: Mention the IRIX problems.

--- doc/posix-functions/remainderf.texi.orig    Thu Mar  8 11:59:05 2012
+++ doc/posix-functions/remainderf.texi Thu Mar  8 11:30:22 2012
@@ -10,7 +10,13 @@
 @itemize
 @item
 This function is missing on some platforms:
-Minix 3.1.8, AIX 5.1, HP-UX 11, IRIX 6.5, Solaris 9, MSVC 9.
+Minix 3.1.8, AIX 5.1, HP-UX 11, older IRIX 6.5, Solaris 9, MSVC 9.
address@hidden
+This function is not declared on some platforms:
+IRIX 6.5.
address@hidden
+This function may go into an endless loop on some platforms:
+IRIX 6.5.
 @end itemize
 
 Portability problems fixed by Gnulib module @code{remainderf-ieee}:
--- m4/remainderf.m4.orig       Thu Mar  8 11:59:06 2012
+++ m4/remainderf.m4    Thu Mar  8 11:29:12 2012
@@ -1,4 +1,4 @@
-# remainderf.m4 serial 4
+# remainderf.m4 serial 5
 dnl Copyright (C) 2012 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
@@ -26,6 +26,11 @@
              # define __NO_MATH_INLINES 1 /* for glibc */
              #endif
              #include <math.h>
+             extern
+             #ifdef __cplusplus
+             "C"
+             #endif
+             float remainderf (float, float);
              float (*funcptr) (float, float) = remainderf;
              float x;
              float y;]],
@@ -37,6 +42,16 @@
   LIBS="$save_LIBS"
   if test $gl_cv_func_remainderf = yes; then
     REMAINDERF_LIBM="$REMAINDER_LIBM"
+
+    save_LIBS="$LIBS"
+    LIBS="$LIBS $REMAINDERF_LIBM"
+    gl_FUNC_REMAINDERF_WORKS
+    LIBS="$save_LIBS"
+    case "$gl_cv_func_remainderf_works" in
+      *yes) ;;
+      *) REPLACE_REMAINDERF=1 ;;
+    esac
+
     m4_ifdef([gl_FUNC_REMAINDERF_IEEE], [
       if test $gl_remainderf_required = ieee && test $REPLACE_REMAINDERF = 0; 
then
         AC_CACHE_CHECK([whether remainderf works according to ISO C 99 with 
IEC 60559],
@@ -50,6 +65,11 @@
 # define __NO_MATH_INLINES 1 /* for glibc */
 #endif
 #include <math.h>
+extern
+#ifdef __cplusplus
+"C"
+#endif
+float remainderf (float, float);
 /* Compare two numbers with ==.
    This is a separate function because IRIX 6.5 "cc -O" miscompiles an
    'x == x' test.  */
@@ -117,3 +137,48 @@
   fi
   AC_SUBST([REMAINDERF_LIBM])
 ])
+
+dnl Test whether remainderf() works.
+dnl It runs into an endless loop on IRIX 6.5.
+AC_DEFUN([gl_FUNC_REMAINDERF_WORKS],
+[
+  AC_REQUIRE([AC_PROG_CC])
+  AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
+  AC_CHECK_FUNCS_ONCE([alarm])
+  AC_CACHE_CHECK([whether remainderf works], [gl_cv_func_remainderf_works],
+    [
+      AC_RUN_IFELSE(
+        [AC_LANG_SOURCE([[
+#include <math.h>
+#if HAVE_ALARM
+# include <unistd.h>
+#endif
+extern
+#ifdef __cplusplus
+"C"
+#endif
+float remainderf (float, float);
+volatile float x;
+volatile float y;
+float z;
+int main ()
+{
+#if HAVE_ALARM
+  alarm (5);
+#endif
+  /* This test fails on IRIX 6.5.  */
+  x = 9.316161e+37f;
+  y = 0.5475547314f;
+  z = remainderf (x, y);
+  return 0;
+}
+]])],
+        [gl_cv_func_remainderf_works=yes],
+        [gl_cv_func_remainderf_works=no],
+        [case "$host_os" in
+           irix*) gl_cv_func_remainderf_works="guessing no";;
+           *)     gl_cv_func_remainderf_works="guessing yes";;
+         esac
+        ])
+    ])
+])




reply via email to

[Prev in Thread] Current Thread [Next in Thread]