Re: module request: sockets.m4

[Bruno Haible]

Sam, Simon,

Sam Steingold wrote:
> Ok, so please do create a module and guarantee the stability. :-)

This wish makes sense: We have a module 'threadlib' which only determines
how to link with the thread library, without providing any replacements.
I can well imagine module 'socketlib' which merely determines the socket
library, without providing any Windows replacement. Here is a proposed
patch.


2010-09-01  Bruno Haible  <address@hidden>

        New module 'socketlib'.
        * modules/socketlib: New file.
        * m4/socketlib.m4: New file, extracted from m4/sockets.m4.
        * m4/sockets.m4 (gl_SOCKETS): Require gl_SOCKETLIB.
        * modules/sockets (Depends-on): Add socketlib.
        Suggested by Sam Steingold <address@hidden>.

============================== modules/socketlib ==============================
Description:
Access to socket primitives.

Files:
m4/socketlib.m4

Depends-on:

configure.ac:
gl_SOCKETLIB

Makefile.am:

Include:

Link:
$(LIBSOCKET)

License:
LGPLv2+

Maintainer:
Simon Josefsson
=============================== m4/socketlib.m4 ===============================
# socketlib.m4 serial 1
dnl Copyright (C) 2008-2010 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

dnl gl_SOCKETLIB
dnl Determines the library to use for socket functions.
dnl Sets and AC_SUBSTs LIBSOCKET.

AC_DEFUN([gl_SOCKETLIB],
[
  gl_PREREQ_SYS_H_WINSOCK2 dnl for HAVE_WINSOCK2_H
  LIBSOCKET=
  if test $HAVE_WINSOCK2_H = 1; then
    dnl Native Windows API (not Cygwin).
    AC_CACHE_CHECK([if we need to call WSAStartup in winsock2.h and -lws2_32],
                   [gl_cv_func_wsastartup], [
      gl_save_LIBS="$LIBS"
      LIBS="$LIBS -lws2_32"
      AC_LINK_IFELSE([AC_LANG_PROGRAM([[
#ifdef HAVE_WINSOCK2_H
# include <winsock2.h>
#endif]], [[
          WORD wVersionRequested = MAKEWORD(1, 1);
          WSADATA wsaData;
          int err = WSAStartup(wVersionRequested, &wsaData);
          WSACleanup ();]])],
        gl_cv_func_wsastartup=yes, gl_cv_func_wsastartup=no)
      LIBS="$gl_save_LIBS"
    ])
    if test "$gl_cv_func_wsastartup" = "yes"; then
      AC_DEFINE([WINDOWS_SOCKETS], [1], [Define if WSAStartup is needed.])
      LIBSOCKET='-lws2_32'
    fi
  else
    dnl Unix API.
    dnl Solaris has most socket functions in libsocket.
    dnl Haiku has most socket functions in libnetwork.
    dnl BeOS has most socket functions in libnet.
    AC_CACHE_CHECK([for library containing setsockopt], [gl_cv_lib_socket], [
      gl_cv_lib_socket=
      AC_LINK_IFELSE([AC_LANG_PROGRAM([[extern
#ifdef __cplusplus
"C"
#endif
char setsockopt();]], [[setsockopt();]])],
        [],
        [gl_save_LIBS="$LIBS"
         LIBS="$gl_save_LIBS -lsocket"
         AC_LINK_IFELSE([AC_LANG_PROGRAM([[extern
#ifdef __cplusplus
"C"
#endif
char setsockopt();]], [[setsockopt();]])],
           [gl_cv_lib_socket="-lsocket"])
         if test -z "$gl_cv_lib_socket"; then
           LIBS="$gl_save_LIBS -lnetwork"
           AC_LINK_IFELSE([AC_LANG_PROGRAM([[extern
#ifdef __cplusplus
"C"
#endif
char setsockopt();]], [[setsockopt();]])],
             [gl_cv_lib_socket="-lnetwork"])
           if test -z "$gl_cv_lib_socket"; then
             LIBS="$gl_save_LIBS -lnet"
             AC_LINK_IFELSE([AC_LANG_PROGRAM([[extern
#ifdef __cplusplus
"C"
#endif
char setsockopt();]], [[setsockopt();]])],
               [gl_cv_lib_socket="-lnet"])
           fi
         fi
         LIBS="$gl_save_LIBS"
        ])
      if test -z "$gl_cv_lib_socket"; then
        gl_cv_lib_socket="none needed"
      fi
    ])
    if test "$gl_cv_lib_socket" != "none needed"; then
      LIBSOCKET="$gl_cv_lib_socket"
    fi
  fi
  AC_SUBST([LIBSOCKET])
])
===============================================================================
--- m4/sockets.m4.orig  Thu Sep  2 01:20:39 2010
+++ m4/sockets.m4       Thu Sep  2 01:19:37 2010
@@ -1,4 +1,4 @@
-# sockets.m4 serial 6
+# sockets.m4 serial 7
 dnl Copyright (C) 2008, 2009, 2010 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
@@ -7,80 +7,7 @@
 AC_DEFUN([gl_SOCKETS],
 [
   AC_REQUIRE([AC_C_INLINE])
-
-  gl_PREREQ_SYS_H_WINSOCK2 dnl for HAVE_WINSOCK2_H
-  LIBSOCKET=
-  if test $HAVE_WINSOCK2_H = 1; then
-    dnl Native Windows API (not Cygwin).
-    AC_CACHE_CHECK([if we need to call WSAStartup in winsock2.h and -lws2_32],
-                   [gl_cv_func_wsastartup], [
-      gl_save_LIBS="$LIBS"
-      LIBS="$LIBS -lws2_32"
-      AC_LINK_IFELSE([AC_LANG_PROGRAM([[
-#ifdef HAVE_WINSOCK2_H
-# include <winsock2.h>
-#endif]], [[
-          WORD wVersionRequested = MAKEWORD(1, 1);
-          WSADATA wsaData;
-          int err = WSAStartup(wVersionRequested, &wsaData);
-          WSACleanup ();]])],
-        gl_cv_func_wsastartup=yes, gl_cv_func_wsastartup=no)
-      LIBS="$gl_save_LIBS"
-    ])
-    if test "$gl_cv_func_wsastartup" = "yes"; then
-      AC_DEFINE([WINDOWS_SOCKETS], [1], [Define if WSAStartup is needed.])
-      LIBSOCKET='-lws2_32'
-    fi
-  else
-    dnl Unix API.
-    dnl Solaris has most socket functions in libsocket.
-    dnl Haiku has most socket functions in libnetwork.
-    dnl BeOS has most socket functions in libnet.
-    AC_CACHE_CHECK([for library containing setsockopt], [gl_cv_lib_socket], [
-      gl_cv_lib_socket=
-      AC_LINK_IFELSE([AC_LANG_PROGRAM([[extern
-#ifdef __cplusplus
-"C"
-#endif
-char setsockopt();]], [[setsockopt();]])],
-        [],
-        [gl_save_LIBS="$LIBS"
-         LIBS="$gl_save_LIBS -lsocket"
-         AC_LINK_IFELSE([AC_LANG_PROGRAM([[extern
-#ifdef __cplusplus
-"C"
-#endif
-char setsockopt();]], [[setsockopt();]])],
-           [gl_cv_lib_socket="-lsocket"])
-         if test -z "$gl_cv_lib_socket"; then
-           LIBS="$gl_save_LIBS -lnetwork"
-           AC_LINK_IFELSE([AC_LANG_PROGRAM([[extern
-#ifdef __cplusplus
-"C"
-#endif
-char setsockopt();]], [[setsockopt();]])],
-             [gl_cv_lib_socket="-lnetwork"])
-           if test -z "$gl_cv_lib_socket"; then
-             LIBS="$gl_save_LIBS -lnet"
-             AC_LINK_IFELSE([AC_LANG_PROGRAM([[extern
-#ifdef __cplusplus
-"C"
-#endif
-char setsockopt();]], [[setsockopt();]])],
-               [gl_cv_lib_socket="-lnet"])
-           fi
-         fi
-         LIBS="$gl_save_LIBS"
-        ])
-      if test -z "$gl_cv_lib_socket"; then
-        gl_cv_lib_socket="none needed"
-      fi
-    ])
-    if test "$gl_cv_lib_socket" != "none needed"; then
-      LIBSOCKET="$gl_cv_lib_socket"
-    fi
-  fi
-  AC_SUBST([LIBSOCKET])
+  AC_REQUIRE([gl_SOCKETLIB])
   gl_PREREQ_SOCKETS
 ])
 
--- modules/sockets.orig        Thu Sep  2 01:20:39 2010
+++ modules/sockets     Thu Sep  2 01:18:04 2010
@@ -8,6 +8,7 @@
 m4/sockets.m4
 
 Depends-on:
+socketlib
 sys_socket
 close-hook