Re: warn-on-use.m4 requires modern M4?

[Eric Blake]

Eric Blake <ebb9 <at> byu.net> writes:

> The problem is not old m4, but old autoconf.
> 
> So, the right patch would be to move gl_AS_VAR_IF out of warnings.m4, and 
make 
> gnulib-common.m4 define a fallback AS_VAR_IF.  I'll take care of that.


From: Eric Blake <address@hidden>
Date: Tue, 12 Jan 2010 09:02:42 -0700
Subject: [PATCH] build: guarantee AS_VAR_IF

The recent addition of warn-on-use.m4 was broken with older autoconf.

* m4/warnings.m4 (gl_WARN_ADD): Use autoconf name.
(gl_AS_VAR_IF): Move...
* m4/gnulib-common.m4 (AS_VAR_IF): ...here.
Reported by Simon Josefsson.

Signed-off-by: Eric Blake <address@hidden>
---
 ChangeLog           |   10 +++++++++-
 m4/gnulib-common.m4 |    8 ++++++++
 m4/warnings.m4      |   12 ++----------
 3 files changed, 19 insertions(+), 11 deletions(-)

diff --git a/ChangeLog b/ChangeLog
index 7e9fc3e..100879c 100644
--- a/ChangeLog
+++ b/ChangeLog
@@ -1,3 +1,11 @@
+2010-01-12  Eric Blake  <address@hidden>
+
+       build: guarantee AS_VAR_IF
+       * m4/warnings.m4 (gl_WARN_ADD): Use autoconf name.
+       (gl_AS_VAR_IF): Move...
+       * m4/gnulib-common.m4 (AS_VAR_IF): ...here.
+       Reported by Simon Josefsson.
+
 2010-01-12  Simon Josefsson  <address@hidden>

        * tests/test-xalloc-die.sh: Use $EXEEXT.
diff --git a/m4/gnulib-common.m4 b/m4/gnulib-common.m4
index d53b9cb..54c5ae4 100644
--- a/m4/gnulib-common.m4
+++ b/m4/gnulib-common.m4
@@ -52,6 +52,14 @@ m4_ifndef([m4_foreach_w],
   [m4_define([m4_foreach_w],
     [m4_foreach([$1], m4_split(m4_normalize([$2]), [ ]), [$3])])])

+# gl_AS_VAR_IF(VAR, VALUE, [IF-MATCH], [IF-NOT-MATCH])
+# ----------------------------------------------------
+# Backport of autoconf-2.63b's macro.
+# Remove this macro when we can assume autoconf >= 2.64.
+m4_ifndef([AS_VAR_IF],
+[m4_define([AS_VAR_IF],
+[AS_IF([test x"AS_VAR_GET([$1])" = x""$2], [$3], [$4])])])
+
 # AC_PROG_MKDIR_P
 # is a backport of autoconf-2.60's AC_PROG_MKDIR_P.
 # Remove this macro when we can assume autoconf >= 2.60.
diff --git a/m4/warnings.m4 b/m4/warnings.m4
index 2745d73..a1e96a2 100644
--- a/m4/warnings.m4
+++ b/m4/warnings.m4
@@ -1,4 +1,4 @@
-# warnings.m4 serial 2
+# warnings.m4 serial 3
 dnl Copyright (C) 2008, 2009, 2010 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
@@ -6,14 +6,6 @@ dnl with or without modifications, as long as this notice is 
preserved.

 dnl From Simon Josefsson

-# gl_AS_VAR_IF(VAR, VALUE, [IF-MATCH], [IF-NOT-MATCH])
-# ----------------------------------------------------
-# Provide the functionality of AS_VAR_IF if Autoconf does not have it.
-m4_ifdef([AS_VAR_IF],
-[m4_copy([AS_VAR_IF], [gl_AS_VAR_IF])],
-[m4_define([gl_AS_VAR_IF],
-[AS_IF([test x"AS_VAR_GET([$1])" = x""$2], [$3], [$4])])])
-
 # gl_AS_VAR_APPEND(VAR, VALUE)
 # ----------------------------
 # Provide the functionality of AS_VAR_APPEND if Autoconf does not have it.
@@ -37,7 +29,7 @@ AC_CACHE_CHECK([whether compiler handles $1], [gl_Warn], [
   CPPFLAGS="$save_CPPFLAGS"
 ])
 AS_VAR_PUSHDEF([gl_Flags], m4_if([$2], [], [[WARN_CFLAGS]], [[$2]]))dnl
-gl_AS_VAR_IF([gl_Warn], [yes], [gl_AS_VAR_APPEND([gl_Flags], [" $1"])])
+AS_VAR_IF([gl_Warn], [yes], [gl_AS_VAR_APPEND([gl_Flags], [" $1"])])
 AS_VAR_POPDEF([gl_Flags])dnl
 AS_VAR_POPDEF([gl_Warn])dnl
 m4_ifval([$2], [AS_LITERAL_IF([$2], [AC_SUBST([$2])], [])])dnl
-- 
1.6.4.2