[bug-gnulib] c-strtod patch for HP-UX pre 11.23

[Paul Eggert]

I installed this to work around the problem that older versions of
HP-UX have a strtold function that returns a struct rather than long
double.

2004-12-24  Paul Eggert  <address@hidden>

        * lib/c-strtod.c (STRTOD): Depend on HAVE_C99_STRTOLD, not
        HAVE_DECL_STRTOLD.
        * m4/c-strtod.m4 (gl_C99_STRTOLD): New macro.
        (gl_C_STRTOD): Use it instead of AC_CHECK_DECLS_ONCE(strtold).

Index: lib/c-strtod.c
===================================================================
RCS file: /cvsroot/gnulib/gnulib/lib/c-strtod.c,v
retrieving revision 1.3
retrieving revision 1.4
diff -p -u -r1.3 -r1.4
--- lib/c-strtod.c      8 Sep 2004 23:09:22 -0000       1.3
+++ lib/c-strtod.c      24 Dec 2004 08:35:58 -0000      1.4
@@ -39,8 +39,8 @@
 # define STRTOD_L strtod_l
 #endif
 
-/* c_strtold falls back on strtod if strtold isn't declared.  */
-#if LONG && HAVE_DECL_STRTOLD
+/* c_strtold falls back on strtod if strtold doesn't conform to C99.  */
+#if LONG && HAVE_C99_STRTOLD
 # define STRTOD strtold
 #else
 # define STRTOD strtod
Index: m4/c-strtod.m4
===================================================================
RCS file: /cvsroot/gnulib/gnulib/m4/c-strtod.m4,v
retrieving revision 1.1
retrieving revision 1.2
diff -p -u -r1.1 -r1.2
--- m4/c-strtod.m4      5 Aug 2004 23:27:27 -0000       1.1
+++ m4/c-strtod.m4      24 Dec 2004 08:36:41 -0000      1.2
@@ -1,4 +1,4 @@
-# c-strtod.m4 serial 3
+# c-strtod.m4 serial 4
 
 # Copyright (C) 2004 Free Software Foundation, Inc.
 
@@ -18,6 +18,32 @@
 
 # Written by Paul Eggert.
 
+AC_DEFUN([gl_C99_STRTOLD],
+[
+  AC_CACHE_CHECK([whether strtold conforms to C99],
+    [gl_cv_func_c99_strtold],
+    [AC_COMPILE_IFELSE(
+       [AC_LANG_PROGRAM(
+          [[/* On HP-UX before 11.23, strtold returns a struct instead of
+               long double.  Reject implementations like that, by requiring
+               compatibility with the C99 prototype.  */
+            #include <stdlib.h>
+            static long double (*p) (char const *, char **) = strtold;
+            static long double
+            test (char const *nptr, char **endptr)
+            {
+              long double r;
+              r = strtold (nptr, endptr);
+              return r;
+            }]],
+           [[return test ("1.0", NULL) != 1 || p ("1.0", NULL) != 1;]])],
+       [gl_cv_func_c99_strtold=yes],
+       [gl_cv_func_c99_strtold=no])])
+  if test $gl_cv_func_c99_strtold = yes; then
+    AC_DEFINE([HAVE_C99_STRTOLD], 1, [Define to 1 if strtold conforms to C99.])
+  fi
+])
+
 AC_DEFUN([gl_C_STRTOD],
 [
   dnl Prerequisites of lib/c-strtod.c.
@@ -29,5 +55,6 @@ AC_DEFUN([gl_C_STRTOLD],
 [
   dnl Prerequisites of lib/c-strtold.c.
   AC_REQUIRE([gl_C_STRTOD])
-  AC_CHECK_DECLS_ONCE([strtold])
+  AC_REQUIRE([gl_C99_STRTOLD])
+  :
 ])