Re: [Bob Proulx] HP-UX 11.0 HP ANSI C

[Paul Eggert]

Bob Proulx writes:

> On ia64 HP-UX 11.23 bundled, crippled, classic K&R compiler does
> compile c-strtold.c fine.  So this looks to be fixed in 11.23 but not
> before.

Thanks for the diagnosis.  I installed the following patch into
coreutils CVS to try to detect this HP-UX incompatibility with C99.  I
don't have an HP-UX box handy to test it with, though.

2004-12-19  Paul Eggert  <address@hidden>

        * lib/c-strtod.c (STRTOD): Depend on HAVE_C99_STRTOLD, not
        HAVE_DECL_STRTOLD.
        * m4/c-strtod.m4 (gl_C99_STRTOLD): New macro.
        (gl_C_STRTOD): Use it instead of AC_CHECK_DECLS_ONCE(strtold).

Index: lib/c-strtod.c
===================================================================
RCS file: /fetish/cu/lib/c-strtod.c,v
retrieving revision 1.7
diff -p -u -r1.7 c-strtod.c
--- lib/c-strtod.c      8 Sep 2004 23:07:04 -0000       1.7
+++ lib/c-strtod.c      20 Dec 2004 07:54:41 -0000
@@ -39,8 +39,8 @@
 # define STRTOD_L strtod_l
 #endif
 
-/* c_strtold falls back on strtod if strtold isn't declared.  */
-#if LONG && HAVE_DECL_STRTOLD
+/* c_strtold falls back on strtod if strtold doesn't conform to C99.  */
+#if LONG && HAVE_C99_STRTOLD
 # define STRTOD strtold
 #else
 # define STRTOD strtod
Index: m4/c-strtod.m4
===================================================================
RCS file: /fetish/cu/m4/c-strtod.m4,v
retrieving revision 1.3
diff -p -u -r1.3 c-strtod.m4
--- m4/c-strtod.m4      4 Aug 2004 22:30:38 -0000       1.3
+++ m4/c-strtod.m4      20 Dec 2004 07:54:41 -0000
@@ -1,4 +1,4 @@
-# c-strtod.m4 serial 3
+# c-strtod.m4 serial 4
 
 # Copyright (C) 2004 Free Software Foundation, Inc.
 
@@ -18,6 +18,32 @@
 
 # Written by Paul Eggert.
 
+AC_DEFUN([gl_C99_STRTOLD],
+[
+  AC_CACHE_CHECK([whether strtold conforms to C99],
+    [gl_cv_func_c99_strtold],
+    [AC_COMPILE_IFELSE(
+       [AC_LANG_PROGRAM(
+          [[/* On HP-UX before 11.23, strtold returns a struct instead of
+               long double.  Reject implementations like that, by requiring
+               compatibility with the C99 prototype.  */
+            #include <stdlib.h>
+            static long double (*p) (char const *, char **) = strtold;
+            static long double
+            test (char const *nptr, char **endptr)
+            {
+              long double r;
+              r = strtold (nptr, endptr);
+              return r;
+            }]],
+           [[return test ("1.0", NULL) != 1 || p ("1.0", NULL) != 1;]])],
+       [gl_cv_func_c99_strtold=yes],
+       [gl_cv_func_c99_strtold=no])])
+  if test $gl_cv_func_c99_strtold = yes; then
+    AC_DEFINE([HAVE_C99_STRTOLD], 1, [Define to 1 if strtold conforms to C99.])
+  fi
+])
+
 AC_DEFUN([gl_C_STRTOD],
 [
   dnl Prerequisites of lib/c-strtod.c.
@@ -29,5 +55,6 @@ AC_DEFUN([gl_C_STRTOLD],
 [
   dnl Prerequisites of lib/c-strtold.c.
   AC_REQUIRE([gl_C_STRTOD])
-  AC_CHECK_DECLS_ONCE([strtold])
+  AC_REQUIRE([gl_C99_STRTOLD])
+  :
 ])