Re: prevent scroll-lock-mode from scrolling?

[lee]

Dmitry Alexandrov <321942@gmail.com> writes:

> lee <lee@yagibdah.de> writes:
>> Can you explain to me why the cursor remains at its position /on the
>> screen/ while I'm scrolling with scroll-lock-mode enabled all the time
>> like it should --- and then suddenly moves when the top or bottom of the
>> buffer contents come into view?  That doesn't make any sense to me; the
>> cursor still shouldn't move.
>
> Given that there is no free space before the first line of a buffer,
> this does make perfect sense with regard to scrolling backward (to the
> top of a buffer).  The other way we would just get stuck with the point
> in the middle of a screen not being able to reach first lines.  The
> scrolling forward behaves the same way for sake of coherence, I guess.

There is no free space beyond the last line of a buffer, either.

It doesn't make sense, though, because scroll-lock means that the cursor
does not move when scrolling.  Why else would I use scroll-lock-mode?

> Anyway, if you look into the code, you’ll see that this behaviour is
> definetely intentional:
>
> (defun scroll-lock-next-line (&optional arg)
>   "Scroll up ARG lines keeping point fixed."
>   (interactive "p")
>   (or arg (setq arg 1))
>   (scroll-lock-update-goal-column)
>   (if (pos-visible-in-window-p (point-max))
>       (forward-line arg)
>     (scroll-up arg))
>   (scroll-lock-move-to-column scroll-lock-temporary-goal-column))
>
> (defun scroll-lock-previous-line (&optional arg)
>   "Scroll up ARG lines keeping point fixed."
>   (interactive "p")
>   (or arg (setq arg 1))
>   (scroll-lock-update-goal-column)
>   (condition-case nil
>       (scroll-down arg)
>     (beginning-of-buffer (forward-line (- arg))))
>   (scroll-lock-move-to-column scroll-lock-temporary-goal-column))

"Scroll up ARG lines keeping point fixed.":  It doesn't keep point fixed
(as I expect) but moves it when the end or start of buffer are near
(which defeats the mode).

> However, if you do not like it, just remove the condition:
>
> (defun my-scroll-lock-next-line (&optional arg)
>   "Scroll up ARG lines keeping point fixed."
>   (interactive "p")
>   (or arg (setq arg 1))
>   (scroll-lock-update-goal-column)
>   (scroll-up arg)
>   (scroll-lock-move-to-column scroll-lock-temporary-goal-column))
>
> (defun my-scroll-lock-previous-line (&optional arg)
>   "Scroll up ARG lines keeping point fixed."
>   (interactive "p")
>   (or arg (setq arg 1))
>   (scroll-lock-update-goal-column)
>   (scroll-down arg)
>   (scroll-lock-move-to-column scroll-lock-temporary-goal-column))
>
> (advice-add 'scroll-lock-next-line :override #'my-scroll-lock-next-line)
> (advice-add 'scroll-lock-previous-line :override 
> #'my-scroll-lock-previous-line)

Thank you very much!  That does the trick --- and I just found out that
I have scroll-preserve-screen-position set to t and forgot about it ages
ago.  The result of that is pretty much what scroll-lock-mode is
supposed to do.

I guess I'm a bit confused because emacs at work and emacs at home are
configured differently.  I should be fine when I set
scroll-preserve-screen-position to t at work, too.

> Also, if you are regularily toggling the ‘scroll-lock-mode’ on and off,
> you might consider to use approach that, one might say, is more
> ‘Emacsish’ — another keychord instead of mode:
>
> (setq scroll-preserve-screen-position 'always)
> (global-set-key (kbd "M-n") #'scroll-up-line)
> (global-set-key (kbd "M-<down>") #'scroll-up-line)
> (global-set-key (kbd "M-p") #'scroll-down-line)
> (global-set-key (kbd "M-<up>") #'scroll-down-line)

The idea was to make use of the ScrollLock key.  So I did that and found
that when scroll-lock-mode is enabled, the point does move when it
shouldn't.

Since what scroll-lock-mode does is achieved by setting
scroll-preserve-screen-position to t, what is the point or purpose of
scroll-lock-mode?  That the cursor moves when it shouldn't?


BTW, it seems that changing scroll-preserve-screen-position requires
restarting emacs to take effect.  Maybe that's what scroll-lock-mode is
for, being able to change the behaviour without restarting?


-- 
GNU Emacs 24.5.1 (x86_64-pc-linux-gnu, X toolkit)
 of 2016-03-18 on heimdali