[Top][All Lists]
[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
pread on HP-UX 11
From: |
Bruno Haible |
Subject: |
pread on HP-UX 11 |
Date: |
Sat, 1 Jan 2011 01:51:15 +0100 |
User-agent: |
KMail/1.9.9 |
On HP-UX 11.11 and 11.31 I'm observing two different failures of the 'pread'
test:
test-pread.c:61: assertion failed
./test-pread.sh[5]: 26534 Abort(coredump)
FAIL: test-pread.sh
test-pread.c:80: assertion failed
./test-pread.sh[5]: 13130 Abort(coredump)
FAIL: test-pread.sh
This patch adds workarounds to gnulib:
2010-12-31 Bruno Haible <address@hidden>
pread: Work around HP-UX 11 bugs.
* m4/pread.m4 (gl_FUNC_PREAD): When pread exists, test whether it works
and set REPLACE_PREAD if not.
* doc/posix-functions/pread.texi: Document the HP-UX 11 bugs.
--- doc/posix-functions/pread.texi.orig Sat Jan 1 01:47:49 2011
+++ doc/posix-functions/pread.texi Fri Dec 31 23:28:30 2010
@@ -11,6 +11,13 @@
@item
This function is missing on some platforms:
HP-UX 10, mingw, BeOS.
address@hidden
+This function returns zero instead of positive values when large file support
+is enabled on some platforms:
+HP-UX 11.11.
address@hidden
+This function does not fail on pipes on some platforms:
+HP-UX 11.31.
@end itemize
Portability problems not fixed by Gnulib:
--- m4/pread.m4.orig Sat Jan 1 01:47:49 2011
+++ m4/pread.m4 Fri Dec 31 23:51:22 2010
@@ -1,4 +1,4 @@
-# pread.m4 serial 2
+# pread.m4 serial 3
dnl Copyright (C) 2009-2010 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
@@ -7,12 +7,82 @@
AC_DEFUN([gl_FUNC_PREAD],
[
AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
+ AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
+
dnl Persuade glibc <unistd.h> to declare pread().
AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
AC_CHECK_FUNCS_ONCE([pread])
- if test $ac_cv_func_pread = no; then
+ if test $ac_cv_func_pread = yes; then
+ dnl On HP-UX 11.11 with _FILE_OFFSET_BITS=64, pread() on a file returns 0
+ dnl instead of a positive value.
+ dnl On HP-UX 11.31, pread() on a pipe does not fail.
+ AC_CACHE_CHECK([whether pread works],
+ [gl_cv_func_pread_works],
+ [
+ dnl Initial guess, used when cross-compiling.
+changequote(,)dnl
+ case "$host_os" in
+ # Guess no on HP-UX.
+ hpux*) gl_cv_func_pread_works="guessing no" ;;
+ # Guess yes otherwise.
+ *) gl_cv_func_pread_works="guessing yes" ;;
+ esac
+changequote([,])dnl
+ gl_save_CPPFLAGS="$CPPFLAGS"
+ CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=64"
+ AC_RUN_IFELSE(
+ [AC_LANG_SOURCE([[
+#include <sys/types.h>
+#include <unistd.h>
+#include <fcntl.h>
+#include <stdio.h>
+ ]],
+ [[
+{
+ int result = 0;
+ /* This test fails on HP-UX 11.00..11.11. */
+ {
+ int fd = open ("conftest.c", O_RDONLY);
+ if (fd < 0)
+ result |= 1;
+ else
+ {
+ char byte_buf;
+ if (pread (fd, &byte_buf, 1, (off_t) 0) != 1)
+ result |= 2;
+ close (fd);
+ }
+ }
+ /* This test fails on HP-UX 11.00..11.31. */
+ {
+ FILE *fp = popen ("echo", "r");
+ if (fp == NULL)
+ result |= 1;
+ else
+ {
+ int fd = fileno (fp);
+ char byte_buf;
+ if (pread (fd, &byte_buf, 1, (off_t) 0) >= 0)
+ result |= 4;
+ pclose (fp);
+ }
+ }
+ return result;
+}]])],
+ [gl_cv_func_pread_works=yes],
+ [gl_cv_func_pread_works=no],
+ [:])
+ CPPFLAGS="$gl_save_CPPFLAGS"
+ ])
+ case "$gl_cv_func_pread_works" in
+ *yes) ;;
+ *) REPLACE_PREAD=1 ;;
+ esac
+ else
HAVE_PREAD=0
+ fi
+ if test $HAVE_PREAD = 0 || test $REPLACE_PREAD = 1; then
AC_LIBOBJ([pread])
fi
])
[Prev in Thread] |
Current Thread |
[Next in Thread] |
- pread on HP-UX 11,
Bruno Haible <=