[Top][All Lists]
[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
Re: btwowc(EOF) hang with gcc 4.4.2
From: |
Bruno Haible |
Subject: |
Re: btwowc(EOF) hang with gcc 4.4.2 |
Date: |
Tue, 22 Dec 2009 22:46:54 +0100 |
User-agent: |
KMail/1.9.9 |
> > Any objections to the following?
> > + * m4/btowc.m4 (gl_FUNC_BTOWC): Add a timeout.
> > + * doc/posix-functions/btowc.texi (btowc): Document the problem.
Here is a proposed change to m4/wchar.m4 that diagnoses the problem before
the btowc test program is even compiled.
2009-12-22 Bruno Haible <address@hidden>
wchar: Diagnose broken combination of glibc and gcc versions and flags.
* m4/wchar.m4 (gl_WCHAR_H_INLINE_OK): New macro.
(gl_WCHAR_H): Invoke it.
* m4/btowc.m4 (gl_FUNC_BTOWC): Require it.
* doc/posix-headers/wchar.texi: Mention the interoperability problem.
--- m4/wchar.m4.orig Tue Dec 22 22:41:53 2009
+++ m4/wchar.m4 Tue Dec 22 22:41:13 2009
@@ -7,7 +7,7 @@
dnl Written by Eric Blake.
-# wchar.m4 serial 26
+# wchar.m4 serial 27
AC_DEFUN([gl_WCHAR_H],
[
@@ -34,6 +34,8 @@
WCHAR_H=wchar.h
fi
+ gl_WCHAR_H_INLINE_OK
+
dnl Prepare for creating substitute <wchar.h>.
dnl Do it always: WCHAR_H may be empty here but can be set later.
dnl Check for <wchar.h> (missing in Linux uClibc when built without wide
@@ -50,6 +52,53 @@
gl_CHECK_NEXT_HEADERS([wchar.h])
])
+dnl Check whether <wchar.h> is usable at all.
+AC_DEFUN([gl_WCHAR_H_INLINE_OK],
+[
+ dnl Test whether <wchar.h> suffers due to the transition from '__inline' to
+ dnl 'gnu_inline'. See <http://sourceware.org/bugzilla/show_bug.cgi?id=4022>
+ dnl and <http://gcc.gnu.org/bugzilla/show_bug.cgi?id=42440>. In summary,
+ dnl glibc version 2.5 or older, together with gcc version 4.3 or newer and
+ dnl the option -std=c99 or -std=gnu99, leads to a broken <wchar.h>.
+ AC_CACHE_CHECK([whether <wchar.h> uses 'inline' correctly],
+ [gl_cv_header_wchar_h_correct_inline],
+ [gl_cv_header_wchar_h_correct_inline=yes
+ AC_LANG_CONFTEST([
+ AC_LANG_SOURCE([[#define wcstod renamed_wcstod
+#include <wchar.h>
+extern int zero (void);
+int main () { return zero(); }
+]])])
+ if AC_TRY_EVAL([ac_compile]); then
+ mv conftest.$ac_objext conftest1.$ac_objext
+ AC_LANG_CONFTEST([
+ AC_LANG_SOURCE([[#define wcstod renamed_wcstod
+#include <wchar.h>
+int zero (void) { return 0; }
+]])])
+ if AC_TRY_EVAL([ac_compile]); then
+ mv conftest.$ac_objext conftest2.$ac_objext
+ if $CC -o conftest$ac_exeext $CFLAGS $LDFLAGS conftest1.$ac_objext
conftest2.$ac_objext $LIBS >&AS_MESSAGE_LOG_FD 2>&1; then
+ :
+ else
+ gl_cv_header_wchar_h_correct_inline=no
+ fi
+ fi
+ fi
+ rm -f conftest1.$ac_objext conftest2.$ac_objext conftest$ac_exeext
+ ])
+ if test $gl_cv_header_wchar_h_correct_inline = no; then
+ AC_MSG_ERROR([<wchar.h> cannot be used with this compiler ($CC $CFLAGS).
+This is a known interoperability problem of glibc <= 2.5 with gcc >= 4.3 in
+C99 mode. You have three options:
+ - Fix your include files, using parts of
+
<http://sourceware.org/git/?p=glibc.git;a=commitdiff;h=b037a293a48718af30d706c2e18c929d0e69a621>,
or
+ - Use a gcc version older than 4.3, or
+ - Don't use the flags -std=c99 or -std=gnu99.
+Configuration aborted.])
+ fi
+])
+
dnl Unconditionally enables the replacement of <wchar.h>.
AC_DEFUN([gl_REPLACE_WCHAR_H],
[
--- m4/btowc.m4.orig Tue Dec 22 22:41:53 2009
+++ m4/btowc.m4 Tue Dec 22 22:31:13 2009
@@ -1,4 +1,4 @@
-# btowc.m4 serial 4
+# btowc.m4 serial 5
dnl Copyright (C) 2008-2009 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
@@ -8,6 +8,11 @@
[
AC_REQUIRE([gl_WCHAR_H_DEFAULTS])
+ dnl Check whether <wchar.h> is usable at all, first. Otherwise the test
+ dnl program below may lead to an endless loop. See
+ dnl <http://gcc.gnu.org/bugzilla/show_bug.cgi?id=42440>.
+ AC_REQUIRE([gl_WCHAR_H_INLINE_OK])
+
AC_CHECK_FUNCS_ONCE([btowc])
if test $ac_cv_func_btowc = no; then
HAVE_BTOWC=0
--- doc/posix-headers/wchar.texi.orig Tue Dec 22 22:41:53 2009
+++ doc/posix-headers/wchar.texi Tue Dec 22 22:37:50 2009
@@ -25,4 +25,9 @@
Portability problems not fixed by Gnulib:
@itemize
address@hidden
+This header file leads to link errors and endless recursions or endless loops
+on some platforms:
+glibc version 2.5 or older, together with gcc version 4.3 or newer and the
+option @samp{-std=c99} or @samp{-std=gnu99}.
@end itemize
- Re: btwowc(EOF) hang with gcc 4.4.2, Eric Blake, 2009/12/15
- Re: btwowc(EOF) hang with gcc 4.4.2, Eric Blake, 2009/12/22
- Re: btwowc(EOF) hang with gcc 4.4.2, Bruno Haible, 2009/12/22
- Re: btwowc(EOF) hang with gcc 4.4.2, Eric Blake, 2009/12/22
- Re: btwowc(EOF) hang with gcc 4.4.2, Bruno Haible, 2009/12/22
- Re: btwowc(EOF) hang with gcc 4.4.2, Eric Blake, 2009/12/22
- Re: btwowc(EOF) hang with gcc 4.4.2, Bruno Haible, 2009/12/22
- Re: btwowc(EOF) hang with gcc 4.4.2, Karl Berry, 2009/12/23