Re: error: possibly undefined macro: AC_CHECK_HEADERS_ONCE

[Sam Steingold]

Hi,

thanks for your replies.

> * Stepan Kasal <address@hidden> [2005-08-07 09:17:30 +0200]:
>
> On Sat, Aug 06, 2005 at 10:51:28PM -0400, Sam Steingold wrote:
>> > * Stepan Kasal <address@hidden> [2005-08-06 17:41:14 +0200]:
>> >
>> >> $ aclocal -I `pwd`/src/m4 --output=src/autoconf/aclocal.m4
>> >
>> > This command examines only ./configure.in.  It doesn't examine the
>> > whole subtree.  In particular, it doesn't know about
>> > modules/regexp/configure.in.
>> 
>> ./configure.ac is the ad hoc concatenation of the the sub-package
>> configures, including modules/regexp/configure.in.
>
> aha, I noticed that in your original example, but later I forgot about it.
>
> Maybe this trick is not working reliably; aclocal was not designed for
> this...  Could you post the ad hoc created configure.in?

appended

-- 
Sam Steingold (http://www.podval.org/~sds) running w2k
<http://truepeace.org> <http://www.mideasttruth.com/> <http://www.dhimmi.com/>
<http://www.palestinefacts.org/> <http://www.openvotingconsortium.org/>
Experience always comes right after it would have been useful.


AC_PREREQ(2.57)
AC_INIT(GNU CLISP, m4_normalize(esyscmd([if test -f version.sh; then . 
./version.sh; else . ../version.sh; fi; echo "${VERSION_NUMBER} 
(${RELEASE_DATE})"])), http://clisp.cons.org/, clisp)
dnl  -*- Autoconf -*- configuration for CLISP
dnl  Bruno Haible 1992-2005
dnl  Sam Steingold 2002-2005
dnl
dnl  configure.in ---<autoconf>--->> configure
dnl
dnl  configure    ---<sh>--->> config.status
dnl                      --->> unixconf.h
dnl          intparam.c  --->> intparam.h
dnl          floatparam.c--->> floatparam.h
dnl          makemake.in --->> makemake
dnl
dnl  makemake     ---<sh>--->> Makefile
dnl
dnl  Makefile     ---<make>--->> lisp.run, lispinit.mem
dnl
dnl
AC_CONFIG_SRCDIR(lispbibl.d)
AC_COPYRIGHT([GNU CLISP Copyright 1989-2005 by Bruno Haible and others
GNU CLISP is distributed under the GNU GPL, see file COPYRIGHT])dnl
AC_REVISION([$Id: configure.in,v 1.96 2005/08/04 22:10:46 sds Exp $])dnl
dnl
AC_MSG_NOTICE([* checks for UNIX variants that set DEFS])
dnl DEFS _ALL_SOURCE
AC_AIX
dnl DEFS _GNU_SOURCE
AC_GNU_SOURCE
dnl DEFS __EXTENSIONS__
gl_USE_SYSTEM_EXTENSIONS
dnl
AC_MSG_NOTICE([* checks for programs])
dnl
dnl sets variable CC
AC_PROG_CC
dnl sets variable CPP
AC_PROG_CPP
dnl sets variable RANLIB
CL_PROG_RANLIB
dnl sets variables INSTALL, INSTALL_DATA, INSTALL_PROGRAM
CL_PROG_INSTALL
dnl sets variable CP
CL_PROG_CP
dnl sets variable LN_S
CL_PROG_LN_S
dnl sets variable HLN
CL_PROG_HLN
dnl sets variable GROFF
AC_CHECK_PROG(GROFF,groff,groff)
dnl sets variable DVIPDF
AC_CHECK_PROG(DVIPDF,dvipdf,dvipdf)
dnl
AC_MSG_NOTICE([* checks for system features])
dnl DEFS _FILE_OFFSET_BITS, _LARGE_FILES
AC_SYS_LARGEFILE
dnl sets variables CC_GCC, GCC_X_NONE
CL_CC_GCC
dnl sets variable CC_CPLUSPLUS
CL_CC_CPLUSPLUS
dnl sets variable CC_NEED_CCPAUX
CL_CC_NEED_CCPAUX
dnl sets variable CC_NEED_DEEMA
CL_CC_NEED_DEEMA
dnl sets variable AS_UNDERSCORE, DEFS ASM_UNDERSCORE
CL_AS_UNDERSCORE
dnl LIBS -lsun
CL_IRIX_SUN
dnl LIBS -lseq, -lsocket
CL_DYNIX_SEQ
dnl LIBS -lsocket
CL_SOCKET
dnl final CC check
CL_CC_WORKS
dnl
AC_MSG_NOTICE([* check for host type])
dnl
dnl sets variables host, host_cpu, host_vendor, host_os
dnl
AC_MSG_NOTICE([* check for add-ons])
dnl
dnl DEFS HAVE_ICONV, ICONV_CONST, set variable LIBICONV
AM_ICONV
dnl USE_NLS CPPFLAGS LIBINTL
dnl Set of all available languages [this is also a /bin/sh/ command!]
ALL_LINGUAS="en de fr es nl ru"
AM_GNU_GETTEXT([external], [need-ngettext])
dnl
dnl set variable LIBSIGSEGV
CL_SIGSEGV
dnl
AC_MSG_NOTICE([* checks for fundamental compiler characteristics])
dnl
dnl DEFS inline
AC_C_INLINE
dnl DEFS void
CL_VOID
dnl DEFS HAVE_BUILTIN_STRLEN
CL_BUILTIN_STRLEN
dnl DEFS HAVE_LONGLONG
gl_AC_TYPE_LONG_LONG
if test $ac_cv_type_long_long = yes; then
  AC_DEFINE(HAVE_LONGLONG,,[Define if the compiler supports the 'long long' 
type])
fi
dnl
AC_MSG_NOTICE([* checks for header files])
dnl
dnl DEFS STDC_HEADERS if exist stdlib.h, stdarg.h, ...
CL_STDC_HEADERS
dnl DEFS HAVE_SYS_INTTYPES_H -- needed for stdint.h.in
AC_CHECK_HEADERS(sys/inttypes.h)
dnl DEFS HAVE_OFFSETOF if offsetof in stddef.h
CL_OFFSETOF
dnl DEFS HAVE_STDBOOL_H, sets variables STDBOOL_H, HAVE__BOOL
gt_STDBOOL_H
dnl DEFS HAVE_STDINT_H, sets variables STDINT_H, HAVE_LONG_64BIT, 
HAVE_LONG_LONG_64BIT
gl_STDINT_H
AC_CHECK_HEADERS(unistd.h)dnl DEFS HAVE_UNISTD_H if exist <unistd.h>
dnl DEFS ACCESS_NEEDS_SYS_FILE_H if sys/file.h is needed for the access() flags
CL_ACCESSFLAGS
dnl DEFS OPEN_NEEDS_SYS_FILE_H if sys/file.h is needed for the open() flags
CL_OPENFLAGS
dnl directory reading functions
CL_DIR_HEADER
dnl DEFS HAVE_SYS_UTSNAME_H
CL_UTSNAME
dnl DEFS HAVE_NETDB_H if exist netdb.h
CL_NETDB
dnl DEFS HAVE_LDAP_H
CL_LDAP
dnl DEFS HAVE_SYS_IPC_H, HAVE_SYS_SHM_H
CL_SHM_H
dnl DEFS HAVE_TERMIOS_H, HAVE_TERMIO_H, ..., HAVE_SGTTY_H
CL_TERM
dnl sets variables X_INCLUDES, X_LIBS, DEFS HAVE_X11
CL_FIND_X
dnl
AC_MSG_NOTICE([* checks for typedefs])
dnl
dnl DEFS CADDR_T
CL_CADDR_T
dnl DEFS SOCKLEN_T
CL_SOCKLEN_T
dnl DEFS SIZEOF_OFF_T
AC_CHECK_SIZEOF([off_t])
dnl DEFS SIZEOF_INO_T
AC_CHECK_SIZEOF([ino_t])
dnl
AC_MSG_NOTICE([* checks for structure members])
dnl
AC_CHECK_MEMBERS([struct dirent.d_namlen],,,[#include <dirent.h>])
dnl DEFS TM_IN_SYS_TIME
AC_STRUCT_TM
dnl
AC_MSG_NOTICE([* checks for functions and declarations])
dnl
dnl set variable GMALLOC
CL_GMALLOC
dnl set variable ALLOCA, DEFS NO_ALLOCA
AC_FUNC_ALLOCA
dnl DEFS HAVE__JMP, LONGJMP_RETURNS
CL_SETJMP
AC_CHECK_FUNCS(memset)
dnl DEFS RETSIGTYPE, SIGTYPE_DOTS
CL_TYPE_SIGNAL
dnl DEFS SIGNALBLOCK_POSIX, SIGNALBLOCK_SYSV, SIGNALBLOCK_BSD
CL_SIGNALBLOCK
dnl DEFS SIGNAL_NEED_REINSTALL
CL_SIGNAL_REINSTALL
dnl DEFS SIGNAL_NEED_UNBLOCK
CL_SIGNAL_UNBLOCK
dnl DEFS SIGNAL_NEED_UNBLOCK_OTHERS
CL_SIGNAL_BLOCK_OTHERS
dnl DEFS HAVE_SIGACTION
CL_SIGACTION
dnl DEFS SIGACTION_NEED_REINSTALL
CL_SIGACTION_REINSTALL
dnl DEFS SIGACTION_NEED_UNBLOCK
CL_SIGACTION_UNBLOCK
dnl DEFS HAVE_SIGINTERRUPT, HAVE_SIGVEC
CL_SIGINTERRUPT
dnl DEFS HAVE_FPU_CONTROL_T, HAVE_SETFPUCW
CL_FPU_CONTROL
dnl DEFS HAVE_RAISE
CL_RAISE
dnl DEFS RETABORTTYPE, ABORT_VOLATILE
CL_ABORT
dnl DEFS HAVE_PERROR_DECL
CL_PERROR
AC_CHECK_FUNCS(strerror)dnl ==> HAVE_STRERROR
dnl DEFS HAVE_PUTENV, HAVE_SETENV
CL_PUTENV
dnl DEFS HAVE_LC_MESSAGES
gt_LC_MESSAGES
dnl DEFS HAVE_GETRLIMIT, HAVE_SETRLIMIT, RLIMIT_RESOURCE_T, SETRLIMIT_CONST
CL_RLIMIT
dnl DEFS HAVE_VFORK_H, vfork
AC_FUNC_VFORK
AC_CHECK_FUNCS(setsid setpgid)dnl ==> HAVE_SETSID, HAVE_SETPGID
dnl DEFS PID_T
CL_WAITPID
dnl DEFS HAVE_SYS_RESOURCE_H, HAVE_GETRUSAGE, RUSAGE_WHO_T, HAVE_SYS_TIMES_H
CL_RUSAGE
dnl DEFS HAVE_GETCWD, GETCWD_SIZE_T
CL_GETCWD
dnl DEFS STAT_MACROS_BROKEN
AC_HEADER_STAT
dnl DEFS HAVE_LSTAT
CL_LSTAT
dnl DEFS HAVE_READLINK
CL_READLINK
dnl DEFS ELOOP_VALUE
CL_ELOOP
dnl DEFS RETCLOSEDIRTYPE, VOID_CLOSEDIR
CL_CLOSEDIR
AC_CHECK_FUNCS(fsync flock)dnl ==> HAVE_FSYNC HAVE_FLOCK
AC_CHECK_HEADERS(sys/file.h)dnl ==> HAVE_SYS_FILE_H
AC_CHECK_HEADERS(sys/statvfs.h sys/statfs.h)dnl ==> HAVE_SYS_STATVFS_H, 
HAVE_SYS_STATFS_H
AC_CHECK_FUNCS(gethostent shutdown)dnl ==> HAVE_GETHOSTENT HAVE_SHUTDOWN
dnl DEFS HAVE_IOCTL, IOCTL_REQUEST_T, IOCTL_ARGUMENT_T, IOCTL_DOTS
dnl HAVE_FIONREAD, NEED_SYS_FILIO_H, NEED_SYS_IOCTL_H, HAVE_RELIABLE_FIONREAD
CL_IOCTL
dnl DEFS HAVE_POLL, HAVE_RELIABLE_POLL
CL_POLL
dnl DEFS HAVE_SELECT, SELECT_WIDTH_T, SELECT_SET_T, SELECT_CONST, 
HAVE_RELIABLE_SELECT
CL_SELECT
AC_CHECK_FUNCS(usleep ualarm setitimer nice ftime realpath)
dnl DEFS HAVE_GETTIMEOFDAY, GETTIMEOFDAY_DOTS, GETTIMEOFDAY_TZP_T
CL_GETTIMEOFDAY
dnl DEFS HAVE_TIMES_CLOCK (only if no ftime())
CL_TIMES_CLOCK
dnl DEFS HAVE_GETHOSTNAME
CL_GETHOSTNAME
dnl DEFS HAVE_GETHOSTBYNAME
CL_GETHOSTBYNAME
dnl DEFS HAVE_CONNECT CONNECT_NAME_T, CONNECT_CONST, CONNECT_ADDRLEN_T
CL_CONNECT
dnl DEFS HAVE_SYS_UN_H, HAVE_SOCKADDR_UN_LEN
CL_UNIXCONN
dnl DEFS HAVE_IPV4, HAVE_IPV6, IPV6_NEED_LINUX_IN6_H, HAVE_INET_PTON,
dnl HAVE_INET_NTOP, HAVE_NETINET_IN_H, HAVE_ARPA_INET_H, RET_INET_ADDR_TYPE,
dnl INET_ADDR_SUFFIX, INET_ADDR_CONST, HAVE_NETINET_TCP_H, SETSOCKOPT_CONST,
dnl SETSOCKOPT_ARG_T, SETSOCKOPT_OPTLEN_T, HAVE_SETSOCKOPT, HAVE_INET_ADDR
CL_TCPCONN
dnl DEFS CODE_ADDRESS_RANGE, MALLOC_ADDRESS_RANGE, SHLIB_ADDRESS_RANGE,
dnl STACK_ADDRESS_RANGE
CL_ADDRESS_RANGE
dnl DEFS HAVE_GETPAGESIZE, RETGETPAGESIZETYPE
CL_GETPAGESIZE
dnl DEFS HAVE_VADVISE
CL_VADVISE
dnl DEFS HAVE_MACH_VM
CL_MACH_VM
dnl DEFS HAVE_MMAP, HAVE_MMAP_ANON, HAVE_MMAP_ANONYMOUS, HAVE_MMAP_DEVZERO,
dnl HAVE_MMAP_DEVZERO_SUN4_29
CL_MMAP
dnl DEFS HAVE_MUNMAP
CL_MUNMAP
dnl DEFS HAVE_MSYNC
CL_MSYNC
dnl DEFS HAVE_MPROTECT, HAVE_WORKING_MPROTECT
CL_MPROTECT
dnl DEFS HAVE_SHM if shm works
CL_SHM
dnl DEFS SHM_RMID_VALID
CL_SHM_RMID
dnl DEFS HAVE_DLOPEN
CL_DYNLOAD
dnl
AC_MSG_NOTICE([* checks for libraries])
dnl
dnl set variable LIBTERMCAP
CL_TERMCAP
if test "$ac_cv_use_readline" = "no" ; then
AC_MSG_NOTICE([not checking for readline])
else dnl DEFS HAVE_READLINE
CL_READLINE
fi
dnl
AC_MSG_NOTICE([* checks for OS services])
dnl
dnl DEFS VALID_FILENAME_CHAR
CL_FILECHARSET
dnl
AC_MSG_NOTICE([* checks for compiler characteristics (arithmetic data types)])
dnl
dnl DEFS __CHAR_UNSIGNED__ if char is unsigned
AC_C_CHAR_UNSIGNED
dnl DEFS FLOAT_DIV0_EXCEPTION, FLOAT_OVERFLOW_EXCEPTION,
dnl      FLOAT_UNDERFLOW_EXCEPTION, FLOAT_INEXACT_EXCEPTION
CL_FLOAT_DIV0
CL_FLOAT_OVERFLOW
CL_FLOAT_UNDERFLOW
CL_FLOAT_INEXACT
dnl DEFS DOUBLE_DIV0_EXCEPTION, DOUBLE_OVERFLOW_EXCEPTION,
dnl      DOUBLE_UNDERFLOW_EXCEPTION, DOUBLE_INEXACT_EXCEPTION
CL_DOUBLE_DIV0
CL_DOUBLE_OVERFLOW
CL_DOUBLE_UNDERFLOW
CL_DOUBLE_INEXACT
dnl builds intparam.h
CL_MACHINE([integer types and behaviour],
${srcdir}/intparam.c,intparam.h,cl_cv_file_intparam_h)
dnl builds floatparam.h
CL_MACHINE([floating-point types and behaviour],
${srcdir}/floatparam.c,floatparam.h,cl_cv_file_floatparam_h)
dnl
AC_MSG_NOTICE([* output file generation])
dnl
dnl gettext po files
dnl
AC_SUBST(PACKAGE)dnl
PACKAGE="clisp"
dnl
dnl
AC_CONFIG_FILES([makemake],[
  echo "#!$SHELL" > makemake.tmp
  echo "# Generated from makemake.in by configure." >> makemake.tmp
  cat makemake >> makemake.tmp
  mv makemake.tmp makemake
  chmod a+x makemake
])
dnl AUTOCONF configuration for Berkeley-DB
dnl Copyright (C) 2003-2005  Sam Steingold <address@hidden>
dnl GNU GPL2

AC_CONFIG_SRCDIR(dbi.lisp)

AC_MSG_NOTICE([ * Berkeley-DB (Tools):])
AC_PROG_CC
AC_PROG_CPP

dnl Search for libdb and define LIBDB, LTLIBDB and INCDB.
AC_CONFIG_AUX_DIR(../../src/build-aux)
AC_LIB_LINKFLAGS([db])

AC_MSG_NOTICE([ * Berkeley-DB (Headers):])
AC_HEADER_STDC
AC_HEADER_TIME
AC_CHECK_HEADERS(sys/time.h time.h)
AC_CHECK_HEADERS(db.h)
if test "$ac_cv_header_db_h" = "no"; then
  AC_MSG_ERROR([cannot find Berkeley-DB headers])
fi

AC_MSG_NOTICE([ * Berkeley-DB (Functions):])
AC_LIB_APPENDTOVAR([LIBS], [$LTLIBDB])
AC_SEARCH_LIBS(db_env_create, db)
if test "$ac_cv_search_db_env_create" = "no"; then
  AC_MSG_ERROR([cannot find Berkeley-DB library])
fi

AC_CHECK_MEMBERS([DB_ENV.get_home, DB_ENV.set_msgcall],,,[#include <db.h>])
if test "$ac_cv_member_DB_ENV_get_home" = "no"; then
  AC_MSG_ERROR([Berkeley-DB version 4.2 or better is required])
fi
AC_CHECK_FUNCS(gettimeofday localtime strftime)
AC_CHECK_SIZEOF(db_recno_t,,[#include <stdio.h>
#include <db.h>])

dnl <http://www.sleepycat.com/docs/ref/upgrade.4.3/stat.html>
AC_CACHE_CHECK([whether DB->stat() accepts TXNid],ac_cv_db_stat_accept_txn,[
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <db.h>],
[[DB db; db.stat(&db,NULL,0,NULL);]])],
ac_cv_db_stat_accept_txn=yes,ac_cv_db_stat_accept_txn=no)])
if test "$ac_cv_db_stat_accept_txn" = "yes"; then
AC_DEFINE(HAVE_DB_STAT_ACCEPT_TXN,1,[Define to 1 if DB->stat() accepts TXNid])
fi

dnl <http://www.sleepycat.com/docs/ref/upgrade.4.3/err.html>
AC_CACHE_CHECK([whether DB_ENV->set_errcall() accepts DBE],
ac_cv_dbe_set_errcall_accept_dbe,[
CFLAGS_save="$CFLAGS"
CFLAGS="$CFLAGS -Werror"
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <db.h>
void my_callback (const DB_ENV* dbe, const char *errpfx, const char *msg) {}],
[[DB_ENV dbe; dbe.set_errcall(&dbe,&my_callback);]])],
ac_cv_dbe_set_errcall_accept_dbe=yes,ac_cv_dbe_set_errcall_accept_dbe=no)
CFLAGS=$CFLAGS_save])
if test "$ac_cv_dbe_set_errcall_accept_dbe" = "yes"; then
AC_DEFINE(HAVE_DBE_SET_ERRCALL_ACCEPT_DBE,1,
[Define to 1 if DB_ENV->set_errcall() accepts DBE])
fi

dnl unannounced!
AC_CACHE_CHECK([whether DB->get_transactional() accepts just 1 argument],
ac_cv_db_get_transactional_1arg,[
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <db.h>],
[[DB db; db.get_transactional(&db);]])],
ac_cv_db_get_transactional_1arg=yes,ac_cv_db_get_transactional_1arg=no)])
if test "$ac_cv_db_get_transactional_1arg" = "yes"; then
AC_DEFINE(HAVE_DB_GET_TRANSACTIONAL_1ARG,1,
[Define to 1 if DB->get_transactional() accepts just 1 argument])
fi

AC_MSG_NOTICE([ * Berkeley-DB (Output):])

AC_MSG_NOTICE([ * Berkeley-DB (Done)])
dnl -*- autoconf -*- script for new-clx
dnl Gilbert Baumann, 1999-10-11
dnl Sam Steingold 2002-06-05

AC_CONFIG_SRCDIR(clx.f)

AC_MSG_NOTICE([ * NEW CLX])
AC_HEADER_TIME
dnl find a path to X11
dnl this generates X_LIBS, X_CFLAGS and X_PRE_LIBS
AC_PATH_XTRA

AC_CHECK_FUNCS(XGetAtomNames)

dnl Look for Xpm
AC_CACHE_CHECK(for Xpm library, gb_cv_have_xpm,
  [ gb_LIBS_save=$LIBS
    gb_CFLAGS_save=$CFLAGS
    LIBS="$X_LIBS -lXpm $X_PRE_LIBS -lX11 $LIBS"
    CFLAGS="$CFLAGS $X_CFLAGS"
    AC_TRY_LINK([#include <X11/xpm.h>],
                [XpmReadFileToPixmap(0,0,0,0,0,0);],
      gb_cv_have_xpm=yes,
      gb_cv_have_xpm=no)
    LIBS=$gb_LIBS_save
    CFLAGS=$gb_CFLAGS_save])

dnl Same thing with XShape
AC_CACHE_CHECK(for X shape extension, gb_cv_have_xshape,
  [ gb_LIBS_save=$LIBS
    gb_CFLAGS_save=$CFLAGS
    LIBS="$X_LIBS -lXext $X_PRE_LIBS -lX11 $LIBS"
    CFLAGS="$CFLAGS $X_CFLAGS"
    AC_TRY_LINK([#include <X11/Xlib.h>
                 #include <X11/Xutil.h>
                 #include <X11/extensions/shape.h>],
                [XShapeQueryExtension(0,0,0);],
      gb_cv_have_xshape=yes,
      gb_cv_have_xshape=no)
    LIBS=$gb_LIBS_save
    CFLAGS=$gb_CFLAGS_save])

dnl Now define some output variables

AC_SUBST(WANTS)         dnl defines WANTS as output variable

dnl Setup X_LIBS as well as WANTS

if test $gb_cv_have_xpm = "yes"; then
    X_LIBS="$X_LIBS -lXpm";
    WANTS="$WANTS -DWANT_XPM=1"
else
    WANTS="$WANTS -DWANT_XPM=0"
fi

if test $gb_cv_have_xshape = "yes"; then
    X_LIBS="$X_LIBS -lXext";
    WANTS="$WANTS -DWANT_XSHAPE=1"
else
    WANTS="$WANTS -DWANT_XSHAPE=0"
fi

dnl And dump what we found:
AC_MSG_NOTICE([ * NEW CLX (output)])

AC_MSG_NOTICE([ * NEW CLX (done)])
dnl AUTOCONF configuration for dirkey
dnl Copyright (C) 2003  Sam Steingold <address@hidden>
dnl GNU GPL2

AC_CONFIG_SRCDIR(dirkey1.lisp)

AC_MSG_NOTICE([ * Dirkey (Tools):])
AC_PROG_CC
AC_PROG_CPP

AC_MSG_NOTICE([ * Dirkey (Headers):])
AC_HEADER_STDC
AC_CHECK_HEADERS(ldap.h gnome.h)

AC_MSG_NOTICE([ * Dirkey (Output):])

AC_MSG_NOTICE([ * Dirkey (Done)])
# configure.ac for FastCGI module

AC_CONFIG_SRCDIR(fastcgi.lisp)

# Checks for programs.
AC_PROG_CC
AC_PROG_LN_S
AC_PROG_MAKE_SET

# Checks for libraries.

# Checks for header files.
AC_HEADER_STDC
AC_CHECK_HEADERS([string.h unistd.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_TYPE_SIZE_T

# Checks for library functions.
AC_CHECK_FUNCS([strchr])

dnl AUTOCONF configuration for I18N
dnl Sam Steingold 2004

AC_CONFIG_SRCDIR(i18n.lisp)

AC_MSG_NOTICE([ * I18N (Headers)])
AC_HEADER_STDC

AC_MSG_NOTICE([ * I18N (locale):])
AC_CHECK_HEADERS(langinfo.h)
AC_CHECK_FUNCS(nl_langinfo localeconv)
AC_CHECK_MEMBERS([struct lconv.int_p_cs_precedes,
struct lconv.int_n_cs_precedes, struct lconv.int_p_sep_by_space,
struct lconv.int_n_sep_by_space, struct lconv.int_p_sign_posn,
struct lconv.int_n_sign_posn],,,[#include <locale.h>])

AC_MSG_NOTICE([ * I18N (Output)])

AC_MSG_NOTICE([ * I18N (Done)])
#
# configure.ac - Input to autoconf for Oracle module
#
# This was originally created with autoscan
#
# $Id: configure.in,v 1.2 2005/08/04 22:02:38 sds Exp $
#

# Process this file with autoconf to produce a configure script.
AC_CONFIG_SRCDIR(oracle.lisp)

# Checks for programs.
AC_PROG_CC
AC_PROG_LN_S
AC_PROG_MAKE_SET

# Checks for libraries.

# Checks for header files.
AC_HEADER_STDC
AC_CHECK_HEADERS([stdlib.h string.h])

# Checks for typedefs, structures, and compiler characteristics.

# Checks for library functions.
AC_FUNC_MALLOC
AC_CHECK_FUNCS([strdup])

dnl AUTOCONF configuration for PARI
dnl Copyright (C) 2004-2005 Sam Steingold <address@hidden>
dnl GNU GPL2

AC_CONFIG_SRCDIR(pari.lisp)

AC_MSG_NOTICE([* PARI (Tools)])
AC_PROG_CC
AC_PROG_CPP
AC_HEADER_STDC

dnl Search for libpari and define LIBPARI, LTLIBPARI and INCPARI.
AC_CONFIG_AUX_DIR(../../src/build-aux)
AC_LIB_LINKFLAGS([pari])

AC_MSG_NOTICE([* PARI (Headers)])
AC_CHECK_HEADERS(pari/pari.h, break)
if test "$ac_cv_header_pari_pari_h" = "no";
then AC_MSG_ERROR([cannot find PARI headers])
fi

AC_MSG_NOTICE([ * PARI (Functions):])
AC_LIB_APPENDTOVAR([LIBS], [$LTLIBPARI])
AC_SEARCH_LIBS(pari_kernel_init)
if test "$ac_cv_search_pari_kernel_init" = "no";
then AC_MSG_ERROR([cannot find PARI library])
fi

AC_MSG_NOTICE([* PARI (Output)])

AC_MSG_NOTICE([* PARI (Done)])
dnl AUTOCONF configuration for PCRE
dnl Sam Steingold 2003-2005
dnl GNU GPL2

AC_CONFIG_SRCDIR(pcre.lisp)

AC_MSG_NOTICE([ * PCRE (Tools)])
AC_PROG_CC
AC_PROG_CPP

dnl Search for libpcre and define LIBPCRE, LTLIBPCRE and INCPCRE.
AC_CONFIG_AUX_DIR(../../src/build-aux)
AC_LIB_LINKFLAGS([pcre])

AC_MSG_NOTICE([ * PCRE (Headers):])
AC_HEADER_STDC
AC_CHECK_HEADERS(pcre.h pcre/pcre.h, break)
if test "$ac_cv_header_pcre_h" = "no" -a "$ac_cv_header_pcre_pcre_h" = "no";
then AC_MSG_ERROR([cannot find PCRE headers])
fi

AC_MSG_NOTICE([ * PCRE (Functions):])
AC_LIB_APPENDTOVAR([LIBS], [$LTLIBPQ])
AC_SEARCH_LIBS(pcre_compile, pcre)
if test "$ac_cv_search_pcre_compile" = "no"; then
  AC_MSG_ERROR([cannot find PCRE library])
fi
AC_CHECK_FUNCS(pcre_get_stringnumber pcre_config)

AC_MSG_NOTICE([ * PCRE (Output)])

AC_MSG_NOTICE([ * PCRE (Done)])
dnl AUTOCONF configuration for postgresql
dnl Copyright (C) 2003-2005  Sam Steingold <address@hidden>
dnl GNU GPL2

AC_CONFIG_SRCDIR(postgresql.lisp)

AC_MSG_NOTICE([* PostgreSQL (Tools)])
AC_PROG_CC
AC_PROG_CPP

dnl Search for libpq and define LIBPQ, LTLIBPQ and INCPQ.
AC_CONFIG_AUX_DIR(../../src/build-aux)
AC_LIB_LINKFLAGS([pq])

AC_MSG_NOTICE([* PostgreSQL (Headers)])
AC_HEADER_STDC
AC_HEADER_TIME
AC_CHECK_HEADERS(postgres_ext.h)
if test "$ac_cv_header_postgres_ext_h" = "no"; then
  AC_MSG_ERROR([cannot find PostgreSQL headers])
fi

AC_MSG_NOTICE([* PostgreSQL (Functions)])
AC_LIB_APPENDTOVAR([LIBS], [$LTLIBPQ])
AC_SEARCH_LIBS(PQconnectdb, pq)
if test "$ac_cv_search_PQconnectdb" = "no"; then
  AC_MSG_ERROR([cannot find PostgreSQL library])
fi
AC_CHECK_FUNCS(PQserverVersion)
if test "$ac_cv_func_PQserverVersion" = "no"; then
  AC_MSG_ERROR([PostgreSQL version 8.0 or better is required])
fi

AC_MSG_NOTICE([* PostgreSQL (Output)])

AC_MSG_NOTICE([* PostgreSQL (Done)])
dnl AUTOCONF configuration for RAWSOCK
dnl Sam Steingold 2003-2004

AC_CONFIG_SRCDIR(sock.lisp)

AC_MSG_NOTICE([* RAWSOCK (Tools)])
AC_PROG_CC
AC_PROG_CPP

AC_MSG_NOTICE([* RAWSOCK (Headers):])
AC_HEADER_STDC
CL_TCPCONN
AC_CHECK_HEADERS([sys/socket.h linux/if_packet.h \
   sys/ioctl.h errno.h stropts.h poll.h sys/un.h])
AC_CHECK_HEADERS([net/if.h],[],[],[
#if HAVE_SYS_SOCKET_H
# include <sys/socket.h>
#endif
])
AC_CHECK_HEADERS([netinet/if_ether.h],[],[],[
#if HAVE_SYS_SOCKET_H
# include <sys/socket.h>
#endif
#if HAVE_NET_IF_H
# include <net/if.h>
#endif
])
if test "$ac_cv_header_sys_socket_h" = "no"; then
AC_CHECK_HEADERS([winsock2.h ws2tcpip.h])dnl windows
fi

AC_MSG_NOTICE([* RAWSOCK (Functions):])
if test "$ac_cv_header_winsock2_h" = "yes"; then
  dnl this is windows, we know that socket() is in ws2_32
  dnl note that AC_SEARCH_LIBS will not work because linking with ws2_32
  dnl requires including <winsock2.h>
  AC_MSG_CHECKING([for socket() in ws2_32])
  LIBS=${LIBS}' -lws2_32';
  AC_LINK_IFELSE(AC_LANG_PROGRAM([#include <winsock2.h>],[socket(0,0,0)]),
  [ac_cv_search_socket=yes
  AC_MSG_RESULT(yes)],
  [ac_cv_search_socket=no
  AC_MSG_RESULT(no)])
else
  AC_SEARCH_LIBS(socket, socket)
fi
if test "$ac_cv_search_socket" = "no"; then
  AC_MSG_FAILURE([cannot find SOCKET library])
fi
AC_CHECK_FUNCS(socketpair sockatmark recvmsg sendmsg htonl htons ntohl ntohs)
dnl AC_CHECK_FUNCS(inet_pton inet_ntop inet_addr inet_ntoa)
CL_POLL
CL_SELECT

AC_MSG_NOTICE([* RAWSOCK (Output)])

AC_MSG_NOTICE([* RAWSOCK (Done)])
dnl AUTOCONF configuration for regex
dnl Bruno Haible 18.4.1995
dnl Sam Steingold 2003-2005

AC_CONFIG_SRCDIR(regexp.lisp)
AC_CONFIG_AUX_DIR(../../src/build-aux)

AC_MSG_NOTICE([* Regexp (Checks)])
AC_PROG_CC
AC_PROG_CPP
AC_HEADER_STDC
AC_CHECK_HEADERS(string.h sys/types.h)
AM_GNU_GETTEXT([external])
gl_C_RESTRICT
gl_FUNC_ALLOCA
gl_INCLUDED_REGEX([regex.c])

# can we use the system-wide regex implementation?
if test "$ac_use_included_regex" = no -a "$cl_cv_regexp" = yes; then
  REGEX_H=""
  REGEX_O=""
  ALLOCA=""
else
  REGEX_H="regex.h"
  REGEX_O="regex.o"
fi
AC_SUBST(REGEX_O)
AC_SUBST(REGEX_H)
AC_MSG_NOTICE([* Regexp (Output)])

AC_MSG_NOTICE([* Regexp (Done)])
dnl AUTOCONF configuration for syscalls
dnl Copyright (C) 2003-2005  Sam Steingold <address@hidden>
dnl GNU GPL2

AC_CONFIG_SRCDIR(posix.lisp)

AC_MSG_NOTICE([ * System Calls (Tools)])
AC_PROG_CC
AC_PROG_CPP

AC_MSG_NOTICE([ * System Calls (Headers)])
AC_HEADER_STDC
AC_HEADER_TIME
CL_UTSNAME
AC_CHECK_HEADERS(errno.h fcntl.h netdb.h sys/resource.h utime.h wchar.h dnl
pwd.h sys/stat.h sys/time.h sys/unistd.h time.h unistd.h syslog.h signal.h dnl
sys/statvfs.h sys/types.h crypt.h utmpx.h stdlib.h shlobj.h)
if test "$ac_cv_header_shlobj_h" = yes ; then
   LIBS=${LIBS}' -luser32 -lole32 -loleaut32 -luuid';
fi
AC_CHECK_SIZEOF(struct timeval,,[#include <stdio.h>
#include <sys/time.h>])
AC_CHECK_SIZEOF(time_t,,[#include <stdio.h>
#include <sys/types.h>])
AC_CHECK_SIZEOF(suseconds_t,,[#include <stdio.h>
#include <sys/types.h>])
if test "$ac_cv_header_utmpx_h" = "yes"; then
 AC_CHECK_MEMBERS([struct utmpx.ut_host],,,[#include <utmpx.h>])
fi
if test "$ac_cv_header_sys_statvfs_h" = "yes"; then
 AC_MSG_CHECKING([whether f_fsid is scalar])
 AC_TRY_COMPILE([#include <sys/statvfs.h>], [struct statvfs x; x.f_fsid = 0;],
  ac_cv_struct_fsid_scalar=yes, ac_cv_struct_fsid_scalar=no)
 AC_MSG_RESULT([$]ac_cv_struct_fsid_scalar)
 if test "$ac_cv_struct_fsid_scalar" = yes; then
  AC_DEFINE([HAVE_SCALAR_FSID], 1,
    [Define to 1 if the f_fsid member of 'struct statvfs' has a integral type.])
 fi
 AC_CHECK_SIZEOF(fsblkcnt_t ,,[#include <stdio.h>
#include <sys/statvfs.h>])
 AC_CHECK_SIZEOF(fsfilcnt_t ,,[#include <stdio.h>
#include <sys/statvfs.h>])
fi
if test "$ac_cv_header_sys_stat_h" = "yes"; then
 AC_CHECK_MEMBERS([struct stat.st_rdev, struct stat.st_blksize, struct 
stat.st_blocks],,,[#include <sys/stat.h>])
fi

AC_MSG_NOTICE([ * System Calls (Functions)])
CL_RLIMIT
AC_CHECK_FUNCS(clock confstr fcntl gethostent sysconf uname dnl
getlogin getpwent getpwnam getpwuid getuid dnl
openlog setlogmask syslog closelog dnl
getpgid setpgrp getsid setpgid setsid kill dnl
endutxent getutxent getutxid getutxline pututxline setutxent dnl
mkfifo mkdir creat mkstemp tempnam mkdtemp dnl
fchmod fchown fstat link stat symlink utime mknod chmod umask fsync sync)
AC_FUNC_CHOWN
AC_SEARCH_LIBS(erf, m)
AC_CHECK_FUNCS(erf erfc lgamma fstatvfs statvfs getpriority setpriority)
AC_CHECK_DECLS(lgamma_r, , , [#include <math.h>] )
AC_CHECK_DECLS(signgam, , , [#include <math.h>] )
AC_SEARCH_LIBS(crypt, crypt)
AC_CHECK_FUNCS(crypt encrypt setkey GlobalMemoryStatusEx)
CL_LSTAT
CL_RUSAGE
if test "$ac_cv_func_setpgrp" = "yes"; then
dnl BSD versions of setpgrp() are identical to setpgid()
AC_CACHE_CHECK([whether setpgrp() is POSIX],ac_cv_func_setpgrp_posix,[
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
#ifdef HAVE_UNISTD_H
#include <unistd.h>
#endif
#include <sys/types.h>
], [[pid_t pid = setpgrp();]])],
ac_cv_func_setpgrp_posix=yes,ac_cv_func_setpgrp_posix=no)])
if test "$ac_cv_func_setpgrp_posix" = "yes"; then
AC_DEFINE(HAVE_SETPGRP_POSIX,1,
[Define to 1 if setpgrp() does not accept arguments])
fi
fi

AC_MSG_NOTICE([ * System Calls (output)])

AC_MSG_NOTICE([ * System Calls (done)])
dnl AUTOCONF configuration for wildcard
dnl Bruno Haible 12.4.1997
dnl Sam Steingold 2003-07-28

AC_CONFIG_SRCDIR(wildcard.lisp)

AC_MSG_NOTICE([ * Wildcard (Checks)])
AC_PROG_CC
AC_PROG_CPP
AC_HEADER_STDC
gl_FUNC_FNMATCH_POSIX
if test -n "$FNMATCH_H"; then
  FNMATCH_O=fnmatch.o
else
  FNMATCH_O=
fi
AC_SUBST(FNMATCH_O)
AC_MSG_NOTICE([ * Wildcard (Output)])

AC_MSG_NOTICE([ * Wildcard (Done)])
dnl AUTOCONF configuration for libz
dnl Sam Steingold 2004-2005

AC_CONFIG_SRCDIR(zlib.lisp)

AC_MSG_NOTICE([ * ZLIB (Tools)])
AC_PROG_CC
AC_PROG_CPP

dnl Search for libz and define LIBZ, LTLIBZ and INCZ.
AC_CONFIG_AUX_DIR(../../src/build-aux)
AC_LIB_LINKFLAGS([z])

AC_MSG_NOTICE([ * ZLIB (Headers)])
AC_HEADER_STDC
AC_CHECK_HEADERS(zlib.h)
if test "$ac_cv_header_zlib_h" = "no" ;
then AC_MSG_ERROR([cannot find ZLIB headers])
fi

AC_MSG_NOTICE([ * ZLIB (Functions):])
AC_SEARCH_LIBS(compress2, z)
if test "$ac_cv_search_compress2" = "no"; then
  AC_MSG_ERROR([cannot find ZLIB library])
fi
AC_CHECK_FUNCS(compressBound)
if test "$ac_cv_func_compressBound" = "no"; then
  AC_MSG_ERROR([ZLIB version 1.2 or better is required])
fi


AC_MSG_NOTICE([ * ZLIB (Output)])

AC_MSG_NOTICE([ * ZLIB (Done)])
AC_OUTPUT