Re: AM_SILENT_RULES doesn't use AS_HELP_STRING?

[Stefano Lattarini]

Hi Jeff.  Thanks for the report.

On Thursday 09 September 2010, Jeff  wrote:
> I feel a bit silly pointing out something so trivial,
Well, I feel a bit sloppy not to having noticed it myself ;-)
> but while looking at my configure --help output, I notice that
> the help messages generated for AM_SILENT_RULES are the only
> ones not aligned with the rest.  Any reason this can't be fixed?
Not that I know of.   In fact, AS_HELP_STRING is there in autoconf 
version 2.62, which is the minimum version Automake requires.

Ralf, what about the attached patch (for master)?  It still lacks
testsuite exposure and ChangeLog entry, but I'm in a hurry right
now.  More this evening or tomorrow.

Regards,
  Stefano

From 7ba6e77f49a824f398436a787b578760ae8be898 Mon Sep 17 00:00:00 2001
From: Stefano Lattarini <address@hidden>
Date: Thu, 9 Sep 2010 17:24:13 +0200
Subject: [PATCH] Use AC_HELP_STRING in AM_SILENT_RULES

---
 configure    |   12 ++++++------
 m4/silent.m4 |   23 ++++++++++++++---------
 2 files changed, 20 insertions(+), 15 deletions(-)

diff --git a/configure b/configure
index b7f3e9b..dafdbce 100755
--- a/configure
+++ b/configure
@@ -1268,8 +1268,8 @@ Optional Features:
   --disable-option-checking  ignore unrecognized --enable/--with options
   --disable-FEATURE       do not include FEATURE (same as --enable-FEATURE=no)
   --enable-FEATURE[=ARG]  include FEATURE [ARG=yes]
-  --enable-silent-rules          less verbose build output (undo: `make V=1')
-  --disable-silent-rules         verbose build output (undo: `make V=0')
+  --enable-silent-rules   less verbose build output (undo: `make V=1')
+  --disable-silent-rules  verbose build output (undo: `make V=0')
 
 Report bugs to <address@hidden>.
 GNU Automake home page: <http://www.gnu.org/software/automake/>.
@@ -2207,10 +2207,10 @@ if test "${enable_silent_rules+set}" = set; then :
   enableval=$enable_silent_rules;
 fi
 
-case $enable_silent_rules in
-yes) AM_DEFAULT_VERBOSITY=0;;
-no)  AM_DEFAULT_VERBOSITY=1;;
-*)   AM_DEFAULT_VERBOSITY=1;;
+case $enable_silent_rules in # (((
+  yes) AM_DEFAULT_VERBOSITY=0;;
+   no) AM_DEFAULT_VERBOSITY=1;;
+    *) AM_DEFAULT_VERBOSITY=1;;
 esac
 AM_BACKSLASH='\'
 
diff --git a/m4/silent.m4 b/m4/silent.m4
index 6d2a1a2..432dd45 100644
--- a/m4/silent.m4
+++ b/m4/silent.m4
@@ -1,24 +1,29 @@
 ##                                                          -*- Autoconf -*-
-# Copyright (C) 2009  Free Software Foundation, Inc.
+# Copyright (C) 2009, 2010 Free Software Foundation, Inc.
 #
 # This file is free software; the Free Software Foundation
 # gives unlimited permission to copy and/or distribute it,
 # with or without modifications, as long as this notice is preserved.
 
-# serial 1
+# serial 2
 
 # AM_SILENT_RULES([DEFAULT])
 # --------------------------
 # Enable less verbose build rules; with the default set to DEFAULT
 # (`yes' being less verbose, `no' or empty being verbose).
 AC_DEFUN([AM_SILENT_RULES],
-[AC_ARG_ENABLE([silent-rules],
-[  --enable-silent-rules          less verbose build output (undo: `make V=1')
-  --disable-silent-rules         verbose build output (undo: `make V=0')])
-case $enable_silent_rules in
-yes) AM_DEFAULT_VERBOSITY=0;;
-no)  AM_DEFAULT_VERBOSITY=1;;
-*)   AM_DEFAULT_VERBOSITY=m4_if([$1], [yes], [0], [1]);;
+[AC_ARG_ENABLE([silent-rules], [dnl
+AS_HELP_STRING(
+  [--enable-silent-rules],
+  [less verbose build output (undo: `make V=1')])
+AS_HELP_STRING(
+  [--disable-silent-rules],
+  [verbose build output (undo: `make V=0')])dnl
+])
+case $enable_silent_rules in @%:@ (((
+  yes) AM_DEFAULT_VERBOSITY=0;;
+   no) AM_DEFAULT_VERBOSITY=1;;
+    *) AM_DEFAULT_VERBOSITY=m4_if([$1], [yes], [0], [1]);;
 esac
 AC_SUBST([AM_DEFAULT_VERBOSITY])dnl
 AM_BACKSLASH='\'
-- 
1.7.1