Re: regression in autoconf 2.65 ?

[Vincent Torri]

Hey

another simpler example of m4 macro that fails with autoconf 2.65.

Error:

configure.ac:791: error: AC_SUBST: `ecore_[job]_cflags' is not a valid shell 
variable name
m4/ecore_check_module.m4:2: ECORE_CHECK_MODULE is expanded from...

Call:

ECORE_CHECK_MODULE([Job], [${want_ecore_job}])

Macro:

AC_DEFUN([ECORE_CHECK_MODULE],
[
m4_pushdef([UP], m4_toupper([[$1]]))dnl
m4_pushdef([DOWN], m4_tolower([[$1]]))dnl

have_ecore_[]m4_defn([DOWN])=no
ecore_[]m4_defn([DOWN])[]_cflags=
ecore_[]m4_defn([DOWN])[]_libs=
want_module=$2

AC_ARG_ENABLE(ecore-[]m4_defn([DOWN]),
   [AC_HELP_STRING(
       [--enable-ecore-[]m4_defn([DOWN])],
       [enable the ecore_]m4_defn([DOWN])[ module. [[default=disabled]]])],
   [want_module=$enableval],
   [want_module=no])

AC_MSG_CHECKING([whether ecore_]m4_defn([DOWN])[ module is to be built])

if test "x${want_module}" = "xyes" ; then
   if test "x$3" = "x" -o "x$3" = "xyes" ; then
      AC_DEFINE([BUILD_ECORE_]m4_defn([UP]), [1], [Build Ecore_$1 Module])
      have_ecore_[]m4_defn([DOWN])="yes"
      ecore_[]m4_defn([DOWN])[]_libs="-lecore_[]m4_defn([DOWN])"
      AC_MSG_RESULT([yes])
   else
      AC_MSG_RESULT([no (dependency failed)])
   fi
else
   AC_MSG_RESULT([no])
fi

AM_CONDITIONAL([BUILD_ECORE_]UP, [test "x$have_ecore_]DOWN[" = "xyes"])

if test "x$have_ecore_[]m4_defn([DOWN])" = "xyes" ; then
   m4_default([$4], [:])
else
   m4_default([$5], [:])
fi

AC_SUBST(ecore_[]m4_defn([DOWN])[]_cflags)
AC_SUBST(ecore_[]m4_defn([DOWN])[]_libs)

m4_popdef([UP])
m4_popdef([DOWN])
])